media-gfx/pstoedit/pstoedit-3.70-r1.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit autotools
   7
   8 DESCRIPTION="Translate PostScript and PDF graphics into other vector formats"
   9 HOMEPAGE="https://sourceforge.net/projects/pstoedit/"
  10 SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
  11
  12 LICENSE="GPL-2"
  13 SLOT="0"
  14 KEYWORDS="alpha amd64 ~arm ~arm64 hppa ia64 ppc ppc64 sparc x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux"
  15 IUSE="emf flash imagemagick plotutils pptx static-libs"
  16
  17 RDEPEND="
  18         >=media-libs/gd-2.0.35-r1:=
  19         >=app-text/ghostscript-gpl-8.71-r1
  20         emf? ( >=media-libs/libemf-1.0.3 )
  21         flash? ( >=media-libs/ming-0.4.3 )
  22         imagemagick? ( >=media-gfx/imagemagick-6.6.1.2[cxx] )
  23         plotutils? ( media-libs/plotutils )
  24         pptx? ( dev-libs/libzip )
  25 "
  26 DEPEND="${RDEPEND}
  27         virtual/pkgconfig
  28 "
  29
  30 PATCHES=(
  31         "${FILESDIR}"/${PN}-3.60-libdl.patch
  32         "${FILESDIR}"/${PN}-3.70-pkgconfig.patch
  33 )
  34
  35 src_prepare() {
  36         default
  37
  38         sed -i \
  39                 -e '/CXXFLAGS="-g"/d' \
  40                 -e 's:-pedantic::' \
  41                 configure.ac || die
  42
  43         eautoreconf
  44 }
  45
  46 src_configure() {
  47         econf \
  48                 $(use_enable static-libs static) \
  49                 $(use_with emf) \
  50                 $(use_with imagemagick magick) \
  51                 $(use_with plotutils libplot) \
  52                 $(use_with flash swf) \
  53                 $(use_with pptx)
  54 }
  55
  56 src_install() {
  57         default
  58         doman doc/pstoedit.1
  59         dodoc doc/*.txt
  60         docinto html
  61         dodoc doc/*.htm
  62
  63         find "${ED}" -name '*.la' -delete
  64 }