media-gfx/openscad/openscad-9999.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit elisp-common git-r3 qmake-utils xdg
   7
   8 SITEFILE="50${PN}-gentoo.el"
   9
  10 DESCRIPTION="The Programmers Solid 3D CAD Modeller"
  11 HOMEPAGE="http://www.openscad.org/"
  12 EGIT_REPO_URI="https://github.com/openscad/openscad.git"
  13
  14 LICENSE="GPL-2"
  15 SLOT="0"
  16 KEYWORDS=""
  17 IUSE="emacs"
  18
  19 DEPEND="
  20         dev-cpp/eigen:3
  21         dev-libs/boost:=
  22         dev-libs/glib:2
  23         dev-libs/gmp:0=
  24         dev-libs/libzip:=
  25         dev-libs/mpfr:0=
  26         dev-qt/qtconcurrent:5
  27         dev-qt/qtcore:5
  28         dev-qt/qtdbus:5
  29         dev-qt/qtgui:5[-gles2-only]
  30         dev-qt/qtmultimedia:5[-gles2-only]
  31         dev-qt/qtopengl:5
  32         media-gfx/opencsg
  33         media-libs/fontconfig:1.0
  34         media-libs/freetype:2
  35         >=media-libs/glew-2.0.0:*
  36         media-libs/harfbuzz
  37         sci-mathematics/cgal:=
  38         >=x11-libs/qscintilla-2.9.4:=[qt5(+)]
  39         emacs? ( >=app-editors/emacs-23.1:* )
  40 "
  41 RDEPEND="${DEPEND}"
  42
  43 src_prepare() {
  44         default
  45
  46         sed -i "s/\/usr\/local/\/usr/g" ${PN}.pro || die
  47
  48         # tries to call ccache even if it's not present otherwise
  49         sed -i '/CONFIG += ccache/d' ${PN}.pro || die
  50 }
  51
  52 src_configure() {
  53         eqmake5 "${PN}.pro"
  54 }
  55
  56 src_compile() {
  57         default
  58
  59         if use emacs ; then
  60                 elisp-compile contrib/*.el
  61         fi
  62 }
  63
  64 src_install() {
  65         emake install INSTALL_ROOT="${D}"
  66
  67         if use emacs; then
  68                 elisp-site-file-install "${FILESDIR}/${SITEFILE}"
  69                 elisp-install ${PN} contrib/*.el contrib/*.elc
  70         fi
  71
  72         einstalldocs
  73 }