media-gfx/krita/krita-4.1.5.ebuild

   1 # Copyright 1999-2018 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 KDE_TEST="forceoptional"
   7 VIRTUALX_REQUIRED="test"
   8 PYTHON_COMPAT=( python3_{4,5,6} )
   9 inherit kde5 python-single-r1
  10
  11 if [[ ${KDE_BUILD_TYPE} = release ]]; then
  12         SRC_URI="mirror://kde/stable/${PN}/${PV%.1}/${P}.tar.gz"
  13         KEYWORDS="~amd64 ~x86"
  14 fi
  15
  16 DESCRIPTION="Free digital painting application. Digital Painting, Creative Freedom!"
  17 HOMEPAGE="https://www.kde.org/applications/graphics/krita/ https://krita.org/"
  18 LICENSE="GPL-3"
  19 IUSE="color-management fftw gif +gsl heif +jpeg openexr pdf qtmedia +raw tiff vc"
  20 REQUIRED_USE="${PYTHON_REQUIRED_USE}"
  21
  22 COMMON_DEPEND="${PYTHON_DEPS}
  23         $(add_frameworks_dep karchive)
  24         $(add_frameworks_dep kcompletion)
  25         $(add_frameworks_dep kconfig)
  26         $(add_frameworks_dep kcoreaddons)
  27         $(add_frameworks_dep kcrash)
  28         $(add_frameworks_dep kguiaddons)
  29         $(add_frameworks_dep ki18n)
  30         $(add_frameworks_dep kiconthemes)
  31         $(add_frameworks_dep kio)
  32         $(add_frameworks_dep kitemmodels)
  33         $(add_frameworks_dep kitemviews)
  34         $(add_frameworks_dep kwidgetsaddons)
  35         $(add_frameworks_dep kwindowsystem)
  36         $(add_frameworks_dep kxmlgui)
  37         $(add_qt_dep qtconcurrent)
  38         $(add_qt_dep qtdbus)
  39         $(add_qt_dep qtdeclarative)
  40         $(add_qt_dep qtgui '-gles2')
  41         $(add_qt_dep qtnetwork)
  42         $(add_qt_dep qtprintsupport)
  43         $(add_qt_dep qtsvg)
  44         $(add_qt_dep qtwidgets)
  45         $(add_qt_dep qtx11extras)
  46         $(add_qt_dep qtxml)
  47         dev-libs/boost:=
  48         dev-python/PyQt5[${PYTHON_USEDEP}]
  49         dev-python/sip[${PYTHON_USEDEP}]
  50         media-gfx/exiv2:=
  51         media-libs/lcms
  52         media-libs/libpng:0=
  53         sys-libs/zlib
  54         virtual/opengl
  55         x11-libs/libX11
  56         x11-libs/libxcb
  57         x11-libs/libXi
  58         color-management? ( media-libs/opencolorio )
  59         fftw? ( sci-libs/fftw:3.0= )
  60         gif? ( media-libs/giflib )
  61         gsl? ( sci-libs/gsl:= )
  62         jpeg? ( virtual/jpeg:0 )
  63         heif? ( media-libs/libheif:= )
  64         openexr? (
  65                 media-libs/ilmbase:=
  66                 media-libs/openexr
  67         )
  68         pdf? ( app-text/poppler[qt5] )
  69         qtmedia? ( $(add_qt_dep qtmultimedia) )
  70         raw? ( media-libs/libraw:= )
  71         tiff? ( media-libs/tiff:0 )
  72 "
  73 DEPEND="${COMMON_DEPEND}
  74         dev-cpp/eigen:3
  75         dev-lang/perl
  76         sys-devel/gettext
  77         vc? ( >=dev-libs/vc-1.1.0 )
  78 "
  79 RDEPEND="${COMMON_DEPEND}
  80         !app-office/calligra:4[calligra_features_krita]
  81         !app-office/calligra-l10n:4[calligra_features_krita(+)]
  82 "
  83
  84 # bug 630508
  85 RESTRICT+=" test"
  86
  87 PATCHES=( "${FILESDIR}/${PN}-4.0.3-tests-optional.patch" )
  88
  89 pkg_setup() {
  90         python-single-r1_pkg_setup
  91         kde5_pkg_setup
  92 }
  93
  94 src_configure() {
  95         # Prevent sandbox violation from FindPyQt5.py module
  96         # See Gentoo-bug 655918
  97         addpredict /dev/dri
  98
  99         local mycmakeargs=(
 100                 $(cmake-utils_use_find_package color-management OCIO)
 101                 $(cmake-utils_use_find_package fftw FFTW3)
 102                 $(cmake-utils_use_find_package gif GIF)
 103                 $(cmake-utils_use_find_package gsl GSL)
 104                 $(cmake-utils_use_find_package heif HEIF)
 105                 $(cmake-utils_use_find_package jpeg JPEG)
 106                 $(cmake-utils_use_find_package openexr OpenEXR)
 107                 $(cmake-utils_use_find_package pdf Poppler)
 108                 $(cmake-utils_use_find_package qtmedia Qt5Multimedia)
 109                 $(cmake-utils_use_find_package raw LibRaw)
 110                 $(cmake-utils_use_find_package tiff TIFF)
 111                 $(cmake-utils_use_find_package vc Vc)
 112         )
 113
 114         kde5_src_configure
 115 }