media-gfx/hugin/hugin-2019.2.0.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 WX_GTK_VER="3.0"
   7 PYTHON_COMPAT=( python3_{6,7,8} )
   8
   9 inherit python-single-r1 wxwidgets cmake-utils eapi7-ver xdg
  10
  11 MY_PV="${PV/_/-}"
  12 MY_P="${PN}-${MY_PV}"
  13
  14 DESCRIPTION="GUI for the creation & processing of panoramic images"
  15 HOMEPAGE="http://hugin.sf.net"
  16 SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.bz2"
  17
  18 LICENSE="GPL-2+ BSD BSD-2 MIT wxWinLL-3 ZLIB FDL-1.2"
  19 SLOT="0"
  20 KEYWORDS="~amd64 ~arm64 ~x86"
  21
  22 LANGS=" ca ca-valencia cs da de en-GB es eu fi fr hu it ja nl pl pt-BR ro ru sk sv zh-CN zh-TW"
  23 IUSE="debug lapack python raw sift $(echo ${LANGS//\ /\ l10n_})"
  24
  25 CDEPEND="
  26         !!dev-util/cocom
  27         dev-db/sqlite:3
  28         dev-libs/boost:=
  29         dev-libs/zthread
  30         >=media-gfx/enblend-4.0
  31         media-gfx/exiv2:=
  32         media-libs/freeglut
  33         media-libs/glew:=
  34         >=media-libs/libpano13-2.9.19_beta1:0=
  35         media-libs/libpng:0=
  36         media-libs/openexr:=
  37         media-libs/tiff:0
  38         >=media-libs/vigra-1.11.0[openexr]
  39         sci-libs/fftw:3.0=
  40         sci-libs/flann
  41         sys-libs/zlib
  42         virtual/glu
  43         virtual/jpeg:0
  44         virtual/opengl
  45         x11-libs/wxGTK:3.0=[X,opengl]
  46         lapack? ( virtual/blas virtual/lapack )
  47         python? ( ${PYTHON_DEPS} )
  48         sift? ( media-gfx/autopano-sift-C )"
  49 RDEPEND="${CDEPEND}
  50         media-libs/exiftool
  51         raw? ( media-gfx/dcraw )"
  52 DEPEND="${CDEPEND}
  53         dev-cpp/tclap
  54         sys-devel/gettext
  55         virtual/pkgconfig
  56         python? ( >=dev-lang/swig-2.0.4 )"
  57
  58 REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
  59
  60 DOCS=( authors.txt README TODO )
  61
  62 S=${WORKDIR}/${PN}-$(ver_cut 1-2).0
  63
  64 pkg_setup() {
  65         use python && python-single-r1_pkg_setup
  66         setup-wxwidgets
  67 }
  68
  69 src_prepare() {
  70         sed -i \
  71                 -e "/COMMAND.*GZIP/d" \
  72                 -e "s/\.gz//g" \
  73                 "${S}"/doc/CMakeLists.txt || die
  74         cmake-utils_src_prepare
  75 }
  76
  77 src_configure() {
  78         local mycmakeargs=(
  79                 -DBUILD_HSI=$(usex python)
  80                 -DENABLE_LAPACK=$(usex lapack)
  81         )
  82         cmake-utils_src_configure
  83 }
  84
  85 src_install() {
  86         cmake-utils_src_install
  87         use python && python_optimize
  88
  89         local lang
  90         for lang in ${LANGS} ; do
  91                 case ${lang} in
  92                         ca) dir=ca_ES;;
  93                         ca-valencia) dir=ca_ES@valencia;;
  94                         cs) dir=cs_CZ;;
  95                         *) dir=${lang/-/_};;
  96                 esac
  97                 if ! use l10n_${lang} ; then
  98                         rm -r "${ED%/}"/usr/share/locale/${dir} || die
  99                 fi
 100         done
 101 }