media-gfx/hugin/hugin-2019.0.0.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 WX_GTK_VER="3.0"
   7 PYTHON_COMPAT=( python{2_7,3_5,3_6,3_7,3_8} )
   8
   9 inherit python-single-r1 wxwidgets cmake-utils eapi7-ver xdg
  10
  11 DESCRIPTION="GUI for the creation & processing of panoramic images"
  12 HOMEPAGE="http://hugin.sf.net"
  13 SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
  14
  15 LICENSE="GPL-2+ BSD BSD-2 MIT wxWinLL-3 ZLIB FDL-1.2"
  16 SLOT="0"
  17 KEYWORDS="amd64 arm64 x86"
  18
  19 LANGS=" ca ca-valencia cs da de en-GB es eu fi fr hu it ja nl pl pt-BR ro ru sk sv zh-CN zh-TW"
  20 IUSE="debug lapack python raw sift $(echo ${LANGS//\ /\ l10n_})"
  21
  22 CDEPEND="
  23         !!dev-util/cocom
  24         dev-db/sqlite:3
  25         dev-libs/boost:=
  26         dev-libs/zthread
  27         >=media-gfx/enblend-4.0
  28         media-gfx/exiv2:=
  29         media-libs/freeglut
  30         media-libs/glew:=
  31         >=media-libs/libpano13-2.9.19_beta1:0=
  32         media-libs/libpng:0=
  33         media-libs/openexr:=
  34         media-libs/tiff:0
  35         >=media-libs/vigra-1.11.0[openexr]
  36         sci-libs/fftw:3.0=
  37         sci-libs/flann
  38         sys-libs/zlib
  39         virtual/glu
  40         virtual/jpeg:0
  41         virtual/opengl
  42         x11-libs/wxGTK:3.0=[X,opengl]
  43         lapack? ( virtual/blas virtual/lapack )
  44         python? ( ${PYTHON_DEPS} )
  45         sift? ( media-gfx/autopano-sift-C )"
  46 RDEPEND="${CDEPEND}
  47         media-libs/exiftool
  48         raw? ( media-gfx/dcraw )"
  49 DEPEND="${CDEPEND}
  50         dev-cpp/tclap
  51         sys-devel/gettext
  52         virtual/pkgconfig
  53         python? ( >=dev-lang/swig-2.0.4 )"
  54
  55 REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
  56
  57 DOCS=( authors.txt README TODO )
  58
  59 PATCHES=( "${FILESDIR}/${P}-exiv2-0.27.1.patch" ) # bug 686366
  60
  61 S=${WORKDIR}/${PN}-$(ver_cut 1-2).0
  62
  63 pkg_setup() {
  64         use python && python-single-r1_pkg_setup
  65         setup-wxwidgets
  66 }
  67
  68 src_prepare() {
  69         sed -i \
  70                 -e "/COMMAND.*GZIP/d" \
  71                 -e "s/\.gz//g" \
  72                 "${S}"/doc/CMakeLists.txt || die
  73         cmake-utils_src_prepare
  74 }
  75
  76 src_configure() {
  77         local mycmakeargs=(
  78                 -DBUILD_HSI=$(usex python)
  79                 -DENABLE_LAPACK=$(usex lapack)
  80         )
  81         cmake-utils_src_configure
  82 }
  83
  84 src_install() {
  85         cmake-utils_src_install
  86         use python && python_optimize
  87
  88         local lang
  89         for lang in ${LANGS} ; do
  90                 case ${lang} in
  91                         ca) dir=ca_ES;;
  92                         ca-valencia) dir=ca_ES@valencia;;
  93                         cs) dir=cs_CZ;;
  94                         *) dir=${lang/-/_};;
  95                 esac
  96                 if ! use l10n_${lang} ; then
  97                         rm -r "${ED%/}"/usr/share/locale/${dir} || die
  98                 fi
  99         done
 100 }