media-gfx/gimp/gimp-2.10.14-r1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 PYTHON_COMPAT=( python2_7 )
   6 GNOME2_EAUTORECONF=yes
   7
   8 inherit autotools gnome2 python-single-r1 virtualx
   9
  10 DESCRIPTION="GNU Image Manipulation Program"
  11 HOMEPAGE="https://www.gimp.org/"
  12 SRC_URI="mirror://gimp/v2.10/${P}.tar.bz2"
  13 LICENSE="GPL-3 LGPL-3"
  14 SLOT="2"
  15 KEYWORDS="amd64 ~ia64 ~ppc64 x86"
  16
  17 IUSE="aalib alsa altivec aqua debug doc gnome heif jpeg2k mng openexr postscript python udev unwind vector-icons webp wmf xpm cpu_flags_x86_mmx cpu_flags_x86_sse"
  18 REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
  19
  20 RESTRICT="!test? ( test )"
  21
  22 COMMON_DEPEND="
  23         app-arch/bzip2
  24         >=app-arch/xz-utils-5.0.0
  25         >=app-text/poppler-0.50[cairo]
  26         >=app-text/poppler-data-0.4.7
  27         >=dev-libs/atk-2.2.0
  28         >=dev-libs/glib-2.56.0:2
  29         dev-libs/libxml2
  30         dev-libs/libxslt
  31         >=gnome-base/librsvg-2.40.6:2
  32         >=media-gfx/mypaint-brushes-1.3.0
  33         >=media-libs/babl-0.1.72
  34         >=media-libs/fontconfig-2.12.4
  35         >=media-libs/freetype-2.1.7
  36         >=media-libs/gegl-0.4.18:0.4[cairo]
  37         >=media-libs/gexiv2-0.10.6
  38         >=media-libs/harfbuzz-0.9.19
  39         >=media-libs/lcms-2.8:2
  40         >=media-libs/libmypaint-1.3.0:=
  41         >=media-libs/libpng-1.6.25:0=
  42         >=media-libs/tiff-3.5.7:0
  43         net-libs/glib-networking[ssl]
  44         sys-libs/zlib
  45         virtual/jpeg:0
  46         >=x11-libs/cairo-1.12.2
  47         >=x11-libs/gdk-pixbuf-2.31:2
  48         >=x11-libs/gtk+-2.24.32:2
  49         x11-libs/libXcursor
  50         >=x11-libs/pango-1.29.4
  51         aalib? ( media-libs/aalib )
  52         alsa? ( >=media-libs/alsa-lib-1.0.0 )
  53         aqua? ( >=x11-libs/gtk-mac-integration-2.0.0 )
  54         heif? ( >=media-libs/libheif-1.3.2:= )
  55         jpeg2k? ( >=media-libs/openjpeg-2.1.0:2= )
  56         mng? ( media-libs/libmng:= )
  57         openexr? ( >=media-libs/openexr-1.6.1:= )
  58         postscript? ( app-text/ghostscript-gpl )
  59         python? (
  60                 ${PYTHON_DEPS}
  61                 $(python_gen_cond_dep '
  62                         >=dev-python/pycairo-1.0.2[${PYTHON_MULTI_USEDEP}]
  63                         >=dev-python/pygtk-2.10.4:2[${PYTHON_MULTI_USEDEP}]
  64                 ')
  65         )
  66         udev? ( dev-libs/libgudev:= )
  67         unwind? ( >=sys-libs/libunwind-1.1.0:= )
  68         webp? ( >=media-libs/libwebp-0.6.0:= )
  69         wmf? ( >=media-libs/libwmf-0.2.8 )
  70         xpm? ( x11-libs/libXpm )
  71 "
  72
  73 RDEPEND="
  74         ${COMMON_DEPEND}
  75         x11-themes/hicolor-icon-theme
  76         gnome? ( gnome-base/gvfs )
  77 "
  78
  79 DEPEND="
  80         ${COMMON_DEPEND}
  81         >=dev-lang/perl-5.10.0
  82         dev-libs/appstream-glib
  83         dev-util/gtk-update-icon-cache
  84         >=dev-util/intltool-0.40.1
  85         sys-apps/findutils
  86         >=sys-devel/automake-1.11
  87         >=sys-devel/gettext-0.19
  88         >=sys-devel/libtool-2.2
  89         virtual/pkgconfig
  90 "
  91
  92 DOCS=( "AUTHORS" "ChangeLog" "HACKING" "NEWS" "README" "README.i18n" )
  93
  94 # Bugs 685210 (and duplicate 691070)
  95 PATCHES=(
  96         "${FILESDIR}/${PN}-2.10_fix_test-appdata.patch"
  97 )
  98
  99 pkg_setup() {
 100         if use python; then
 101                 python-single-r1_pkg_setup
 102         fi
 103 }
 104
 105 src_prepare() {
 106         # Disable system CFLAGS suppressing on SSE{2,4.1} support tests by addition of {SSE2,SSE4_1}_EXTRA_CFLAGS: bug #702554
 107         sed -i -e 's:\$intrinsics_save_CFLAGS \$SSE2_EXTRA_CFLAGS:\$SSE2_EXTRA_CFLAGS \$intrinsics_save_CFLAGS:' \
 108                 -e 's:\$intrinsics_save_CFLAGS \$SSE4_1_EXTRA_CFLAGS:\$SSE4_1_EXTRA_CFLAGS \$intrinsics_save_CFLAGS:' configure.ac || die
 109
 110         sed -i -e 's/== "xquartz"/= "xquartz"/' configure.ac || die #494864
 111         sed 's:-DGIMP_DISABLE_DEPRECATED:-DGIMP_protect_DISABLE_DEPRECATED:g' -i configure.ac || die #615144
 112
 113         gnome2_src_prepare  # calls eautoreconf
 114
 115         sed 's:-DGIMP_protect_DISABLE_DEPRECATED:-DGIMP_DISABLE_DEPRECATED:g' -i configure || die #615144
 116         fgrep -q GIMP_DISABLE_DEPRECATED configure || die #615144, self-test
 117 }
 118
 119 _adjust_sandbox() {
 120         # Bugs #569738 and #591214
 121         local nv
 122         for nv in /dev/nvidia-uvm /dev/nvidiactl /dev/nvidia{0..9} ; do
 123                 # We do not check for existence as they may show up later
 124                 # https://bugs.gentoo.org/show_bug.cgi?id=569738#c21
 125                 addwrite "${nv}"
 126         done
 127
 128         addwrite /dev/dri/  # bugs #574038 and #684886
 129         addwrite /dev/ati/  # bug #589198
 130         addwrite /proc/mtrr  # bug #589198
 131 }
 132
 133 src_configure() {
 134         _adjust_sandbox
 135
 136         local myconf=(
 137                 GEGL="${EPREFIX}"/usr/bin/gegl-0.4
 138                 GDBUS_CODEGEN="${EPREFIX}"/bin/false
 139
 140                 --enable-default-binary
 141
 142                 --enable-mp
 143                 --with-appdata-test
 144                 --with-bug-report-url=https://bugs.gentoo.org/
 145                 --with-xmc
 146                 --without-libbacktrace
 147                 --without-webkit
 148                 --without-xvfb-run
 149                 $(use_enable altivec)
 150                 $(use_enable cpu_flags_x86_mmx mmx)
 151                 $(use_enable cpu_flags_x86_sse sse)
 152                 $(use_enable python)
 153                 $(use_enable vector-icons)
 154                 $(use_with aalib aa)
 155                 $(use_with alsa)
 156                 $(use_with !aqua x)
 157                 $(use_with heif libheif)
 158                 $(use_with jpeg2k jpeg2000)
 159                 $(use_with mng libmng)
 160                 $(use_with openexr)
 161                 $(use_with postscript gs)
 162                 $(use_with udev gudev)
 163                 $(use_with unwind libunwind)
 164                 $(use_with webp)
 165                 $(use_with wmf)
 166                 $(use_with xpm libxpm)
 167         )
 168
 169         gnome2_src_configure "${myconf[@]}"
 170 }
 171
 172 src_compile() {
 173         export XDG_DATA_DIRS="${EPREFIX}"/usr/share  # bug 587004
 174         gnome2_src_compile
 175 }
 176
 177 # for https://bugs.gentoo.org/664938
 178 _rename_plugins() {
 179         einfo 'Renaming plug-ins to not collide with pre-2.10.6 file layout (bug #664938)...'
 180         local prepend=gimp-org-
 181         (
 182                 cd "${ED%/}"/usr/$(get_libdir)/gimp/2.0/plug-ins || exit 1
 183                 for plugin_slash in $(ls -d1 */); do
 184                     plugin=${plugin_slash%/}
 185                     if [[ -f ${plugin}/${plugin} ]]; then
 186                         # NOTE: Folder and file name need to match for Gimp to load that plug-in
 187                         #       so "file-svg/file-svg" becomes "${prepend}file-svg/${prepend}file-svg"
 188                         mv ${plugin}/{,${prepend}}${plugin} || exit 1
 189                         mv {,${prepend}}${plugin} || exit 1
 190                     fi
 191                 done
 192         )
 193 }
 194
 195 src_test() {
 196         virtx emake check
 197 }
 198
 199 src_install() {
 200         gnome2_src_install
 201
 202         if use python; then
 203                 python_optimize
 204         fi
 205
 206         # Workaround for bug #321111 to give GIMP the least
 207         # precedence on PDF documents by default
 208         mv "${ED%/}"/usr/share/applications/{,zzz-}gimp.desktop || die
 209
 210         find "${D}" -name '*.la' -type f -delete || die
 211
 212         # Prevent dead symlink gimp-console.1 from downstream man page compression (bug #433527)
 213         local gimp_app_version=$(get_version_component_range 1-2)
 214         mv "${ED%/}"/usr/share/man/man1/gimp-console{-${gimp_app_version},}.1 || die
 215
 216         # Remove gimp devel-docs html files if user doesn't need it
 217         if ! use doc; then
 218                 rm -r "${ED%/}"/usr/share/gtk-doc || die
 219         fi
 220
 221         _rename_plugins || die
 222 }
 223
 224 pkg_postinst() {
 225         gnome2_pkg_postinst
 226 }
 227
 228 pkg_postrm() {
 229         gnome2_pkg_postrm
 230 }