media-gfx/gimp/gimp-2.10.10-r1.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 PYTHON_COMPAT=( python2_7 )
   6 GNOME2_EAUTORECONF=yes
   7
   8 inherit autotools gnome2 python-single-r1 virtualx
   9
  10 DESCRIPTION="GNU Image Manipulation Program"
  11 HOMEPAGE="https://www.gimp.org/"
  12 SRC_URI="mirror://gimp/v2.10/${P}.tar.bz2"
  13 LICENSE="GPL-3 LGPL-3"
  14 SLOT="2"
  15 KEYWORDS="~amd64 ~x86"
  16
  17 IUSE="aalib alsa altivec aqua debug doc gnome heif jpeg2k mng openexr postscript python udev unwind vector-icons webp wmf xpm cpu_flags_x86_mmx cpu_flags_x86_sse"
  18 REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
  19
  20 RESTRICT="!test? ( test )"
  21
  22 COMMON_DEPEND="
  23         app-arch/bzip2
  24         >=app-arch/xz-utils-5.0.0
  25         >=app-text/poppler-0.50[cairo]
  26         >=app-text/poppler-data-0.4.7
  27         >=dev-libs/atk-2.2.0
  28         >=dev-libs/glib-2.54.2:2
  29         dev-libs/libxml2
  30         dev-libs/libxslt
  31         >=gnome-base/librsvg-2.40.6:2
  32         >=media-gfx/mypaint-brushes-1.3.0
  33         >=media-libs/babl-0.1.62
  34         >=media-libs/fontconfig-2.12.4
  35         >=media-libs/freetype-2.1.7
  36         >=media-libs/gegl-0.4.14:0.4[cairo]
  37         >=media-libs/gexiv2-0.10.6
  38         >=media-libs/harfbuzz-0.9.19
  39         >=media-libs/lcms-2.8:2
  40         >=media-libs/libmypaint-1.3.0:=
  41         >=media-libs/libpng-1.6.25:0=
  42         >=media-libs/tiff-3.5.7:0
  43         net-libs/glib-networking[ssl]
  44         sys-libs/zlib
  45         virtual/jpeg:0
  46         >=x11-libs/cairo-1.12.2
  47         >=x11-libs/gdk-pixbuf-2.30.8:2
  48         >=x11-libs/gtk+-2.24.32:2
  49         x11-libs/libXcursor
  50         >=x11-libs/pango-1.29.4
  51         aalib? ( media-libs/aalib )
  52         alsa? ( >=media-libs/alsa-lib-1.0.0 )
  53         aqua? ( >=x11-libs/gtk-mac-integration-2.0.0 )
  54         heif? ( >=media-libs/libheif-1.1.0:= )
  55         jpeg2k? ( >=media-libs/openjpeg-2.1.0:2= )
  56         mng? ( media-libs/libmng:= )
  57         openexr? ( >=media-libs/openexr-1.6.1:= )
  58         postscript? ( app-text/ghostscript-gpl )
  59         python? (
  60                 ${PYTHON_DEPS}
  61                 >=dev-python/pycairo-1.0.2[${PYTHON_USEDEP}]
  62                 >=dev-python/pygtk-2.10.4:2[${PYTHON_USEDEP}]
  63         )
  64         udev? ( dev-libs/libgudev:= )
  65         unwind? ( >=sys-libs/libunwind-1.1.0:= )
  66         webp? ( >=media-libs/libwebp-0.6.0:= )
  67         wmf? ( >=media-libs/libwmf-0.2.8 )
  68         xpm? ( x11-libs/libXpm )
  69 "
  70
  71 RDEPEND="
  72         ${COMMON_DEPEND}
  73         x11-themes/hicolor-icon-theme
  74         gnome? ( gnome-base/gvfs )
  75 "
  76
  77 DEPEND="
  78         ${COMMON_DEPEND}
  79         >=dev-lang/perl-5.10.0
  80         dev-libs/appstream-glib
  81         dev-util/gtk-update-icon-cache
  82         >=dev-util/intltool-0.40.1
  83         sys-apps/findutils
  84         >=sys-devel/automake-1.11
  85         >=sys-devel/gettext-0.19
  86         >=sys-devel/libtool-2.2
  87         virtual/pkgconfig
  88 "
  89
  90 DOCS=( "AUTHORS" "ChangeLog" "HACKING" "NEWS" "README" "README.i18n" )
  91
  92 # Bugs 685210 (and duplicate 691070)
  93 PATCHES=(
  94         "${FILESDIR}/${PN}-2.10_fix_test-appdata.patch"
  95 )
  96
  97 pkg_setup() {
  98         if use python; then
  99                 python-single-r1_pkg_setup
 100         fi
 101 }
 102
 103 src_prepare() {
 104         sed -i -e 's/== "xquartz"/= "xquartz"/' configure.ac || die #494864
 105         sed 's:-DGIMP_DISABLE_DEPRECATED:-DGIMP_protect_DISABLE_DEPRECATED:g' -i configure.ac || die #615144
 106
 107         gnome2_src_prepare  # calls eautoreconf
 108
 109         sed 's:-DGIMP_protect_DISABLE_DEPRECATED:-DGIMP_DISABLE_DEPRECATED:g' -i configure || die #615144
 110         fgrep -q GIMP_DISABLE_DEPRECATED configure || die #615144, self-test
 111 }
 112
 113 _adjust_sandbox() {
 114         # Bugs #569738 and #591214
 115         local nv
 116         for nv in /dev/nvidia-uvm /dev/nvidiactl /dev/nvidia{0..9} ; do
 117                 # We do not check for existence as they may show up later
 118                 # https://bugs.gentoo.org/show_bug.cgi?id=569738#c21
 119                 addwrite "${nv}"
 120         done
 121
 122         addwrite /dev/dri/  # bugs #574038 and #684886
 123         addwrite /dev/ati/  # bug #589198
 124         addwrite /proc/mtrr  # bug #589198
 125 }
 126
 127 src_configure() {
 128         _adjust_sandbox
 129
 130         local myconf=(
 131                 GEGL="${EPREFIX}"/usr/bin/gegl-0.4
 132                 GDBUS_CODEGEN="${EPREFIX}"/bin/false
 133
 134                 --enable-default-binary
 135
 136                 --enable-mp
 137                 --with-appdata-test
 138                 --with-bug-report-url=https://bugs.gentoo.org/
 139                 --with-xmc
 140                 --without-libbacktrace
 141                 --without-webkit
 142                 --without-xvfb-run
 143                 $(use_enable altivec)
 144                 $(use_enable cpu_flags_x86_mmx mmx)
 145                 $(use_enable cpu_flags_x86_sse sse)
 146                 $(use_enable python)
 147                 $(use_enable vector-icons)
 148                 $(use_with aalib aa)
 149                 $(use_with alsa)
 150                 $(use_with !aqua x)
 151                 $(use_with heif libheif)
 152                 $(use_with jpeg2k jpeg2000)
 153                 $(use_with mng libmng)
 154                 $(use_with openexr)
 155                 $(use_with postscript gs)
 156                 $(use_with udev gudev)
 157                 $(use_with unwind libunwind)
 158                 $(use_with webp)
 159                 $(use_with wmf)
 160                 $(use_with xpm libxpm)
 161         )
 162
 163         gnome2_src_configure "${myconf[@]}"
 164 }
 165
 166 src_compile() {
 167         export XDG_DATA_DIRS="${EPREFIX}"/usr/share  # bug 587004
 168         gnome2_src_compile
 169 }
 170
 171 # for https://bugs.gentoo.org/664938
 172 _rename_plugins() {
 173         einfo 'Renaming plug-ins to not collide with pre-2.10.6 file layout (bug #664938)...'
 174         local prepend=gimp-org-
 175         (
 176                 cd "${ED%/}"/usr/$(get_libdir)/gimp/2.0/plug-ins || exit 1
 177                 for plugin_slash in $(ls -d1 */); do
 178                     plugin=${plugin_slash%/}
 179                     if [[ -f ${plugin}/${plugin} ]]; then
 180                         # NOTE: Folder and file name need to match for Gimp to load that plug-in
 181                         #       so "file-svg/file-svg" becomes "${prepend}file-svg/${prepend}file-svg"
 182                         mv ${plugin}/{,${prepend}}${plugin} || exit 1
 183                         mv {,${prepend}}${plugin} || exit 1
 184                     fi
 185                 done
 186         )
 187 }
 188
 189 src_test() {
 190         virtx emake check
 191 }
 192
 193 src_install() {
 194         gnome2_src_install
 195
 196         if use python; then
 197                 python_optimize
 198         fi
 199
 200         # Workaround for bug #321111 to give GIMP the least
 201         # precedence on PDF documents by default
 202         mv "${ED%/}"/usr/share/applications/{,zzz-}gimp.desktop || die
 203
 204         find "${D}" -name '*.la' -type f -delete || die
 205
 206         # Prevent dead symlink gimp-console.1 from downstream man page compression (bug #433527)
 207         local gimp_app_version=$(get_version_component_range 1-2)
 208         mv "${ED%/}"/usr/share/man/man1/gimp-console{-${gimp_app_version},}.1 || die
 209
 210         # Remove gimp devel-docs html files if user doesn't need it
 211         if ! use doc; then
 212                 rm -r "${ED%/}"/usr/share/gtk-doc || die
 213         fi
 214
 215         _rename_plugins || die
 216 }
 217
 218 pkg_postinst() {
 219         gnome2_pkg_postinst
 220 }
 221
 222 pkg_postrm() {
 223         gnome2_pkg_postrm
 224 }