media-gfx/freecad/freecad-0.13.1830-r1.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6
   7 PYTHON_COMPAT=( python2_7 )
   8
   9 inherit cmake-utils eutils fortran-2 multilib python-single-r1
  10
  11 DESCRIPTION="QT based Computer Aided Design application"
  12 HOMEPAGE="http://www.freecadweb.org/"
  13 SRC_URI="mirror://sourceforge/free-cad/${P}.tar.gz"
  14
  15 LICENSE="GPL-2"
  16 SLOT="0"
  17 KEYWORDS="~amd64 ~x86"
  18 IUSE=""
  19
  20 COMMON_DEPEND="dev-cpp/eigen:3
  21         dev-games/ode
  22         <dev-libs/boost-1.57
  23         dev-libs/libf2c
  24         dev-libs/libspnav[X]
  25         dev-libs/xerces-c[icu]
  26         dev-python/matplotlib
  27         dev-qt/designer:4
  28         dev-qt/qtgui:4
  29         dev-qt/qtopengl:4
  30         dev-qt/qtsvg:4
  31         dev-qt/qtwebkit:4
  32         dev-qt/qtxmlpatterns:4
  33         media-libs/SoQt
  34         media-libs/coin[doc]
  35         sci-libs/opencascade:6.7.1
  36         sys-libs/zlib
  37         virtual/glu
  38         ${PYTHON_DEPS}"
  39 RDEPEND="${COMMON_DEPEND}
  40         dev-qt/assistant:4
  41         dev-python/pycollada
  42         dev-python/pivy
  43         dev-python/PyQt4[svg]
  44         dev-python/pyopencl
  45         dev-python/numpy"
  46 DEPEND="${COMMON_DEPEND}
  47         >=dev-lang/swig-2.0.4-r1:0"
  48
  49 # http://bugs.gentoo.org/show_bug.cgi?id=352435
  50 # https://www.gentoo.org/foundation/en/minutes/2011/20110220_trustees.meeting_log.txt
  51 RESTRICT="bindist mirror"
  52
  53 # TODO:
  54 #   DEPEND and RDEPEND:
  55 #               salome-smesh - science overlay
  56 #               zipio++ - not in portage yet
  57
  58 pkg_setup() {
  59         fortran-2_pkg_setup
  60         python-single-r1_pkg_setup
  61
  62         [ -z "${CASROOT}" ] && die "empty \$CASROOT, run eselect opencascade set or define otherwise"
  63 }
  64
  65 src_prepare() {
  66         einfo remove bundled libs
  67         rm -rf src/3rdParty/{boost,Pivy*}
  68
  69         epatch "${FILESDIR}"/${P}-remove-qt3-support.patch
  70         epatch "${FILESDIR}"/${P}-cmake-2.8.12.patch
  71         epatch "${FILESDIR}"/${P}-CMakefile.patch
  72         epatch "${FILESDIR}"/${P}-avoid-include-salome.patch
  73         epatch "${FILESDIR}"/${P}-startpage-links.patch
  74
  75         # disable Machining Distortion workbench because FEM will be disabled in src_configure()
  76         # and also because the same module has been removed upstream (commit c0e2c9)
  77         epatch "${FILESDIR}"/${P}-no-machdist.patch
  78
  79         epatch  "${FILESDIR}"/${PN}-0.12.5284-occ-6.6.patch
  80         epatch  "${FILESDIR}"/${P}-occ-6.7.patch
  81
  82         einfo "Patching cMake/FindCoin3DDoc.cmake ..."
  83         local my_coin_version=$(best_version media-libs/coin)
  84         local my_coin_path="${EROOT}"usr/share/doc/${my_coin_version##*/}/html
  85         sed -e "s:/usr/share/doc/libcoin60-doc/html:${my_coin_path}:" \
  86                 -i cMake/FindCoin3DDoc.cmake || die
  87 }
  88
  89 src_configure() {
  90         local mycmakeargs=(
  91                 -DOCC_INCLUDE_DIR="${CASROOT}"/inc
  92                 -DOCC_INCLUDE_PATH="${CASROOT}"/inc
  93                 -DOCC_LIBRARY="${CASROOT}"/lib/libTKernel.so
  94                 -DOCC_LIBRARY_DIR="${CASROOT}"/lib
  95                 -DOCC_LIB_PATH="${CASROOT}"/lib
  96                 -DCOIN3D_INCLUDE_DIR="${EROOT}"usr/include/coin
  97                 -DCOIN3D_LIBRARY="${EROOT}"usr/$(get_libdir)/libCoin.so
  98                 -DSOQT_LIBRARY="${EROOT}"usr/$(get_libdir)/libSoQt.so
  99                 -DSOQT_INCLUDE_PATH="${EROOT}"usr/include/coin
 100                 -DCMAKE_INSTALL_PREFIX="${EROOT}"usr/$(get_libdir)/${P}
 101                 -DCMAKE_INSTALL_DATADIR="${EROOT}"usr/share/${P}/
 102                 -DCMAKE_INSTALL_DOCDIR="${EROOT}"usr/share/doc/${P}/
 103                 -DCMAKE_INSTALL_INCLUDEDIR="${EROOT}"usr/include/${P}/
 104                 -DFREECAD_USE_EXTERNAL_PIVY="ON"
 105                 -DFREECAD_BUILD_FEM="OFF"
 106         )
 107
 108         # TODO to remove embedded dependencies:
 109         #
 110         #       -DFREECAD_USE_EXTERNAL_ZIPIOS="ON" -- this option needs zipios++ but it's not yet in portage so the embedded zipios++
 111         #                (under src/zipios++) will be used
 112         #       salomesmesh is in 3rdparty but upstream's find_package function is not complete yet to compile against external version
 113         #                (external salomesmesh is available in "science" overlay)
 114
 115         cmake-utils_src_configure
 116         ewarn "${P} will be built against opencascade version ${CASROOT}"
 117 }
 118
 119 src_install() {
 120         cmake-utils_src_install
 121
 122         prune_libtool_files
 123
 124         make_wrapper FreeCAD \
 125                 "${EROOT}"usr/$(get_libdir)/${P}/bin/FreeCAD \
 126                 "" "${EROOT}"usr/$(get_libdir)/${P}/lib
 127         make_wrapper FreeCADCmd \
 128                 "${EROOT}"usr/$(get_libdir)/${P}/bin/FreeCADCmd \
 129                 "" "${EROOT}"usr/$(get_libdir)/${P}/lib
 130
 131         newicon src/Main/icon.ico ${PN}.ico
 132         make_desktop_entry FreeCAD
 133
 134         dodoc README.Linux ChangeLog.txt
 135
 136         # disable compression of QT assistant help files
 137         >> "${ED}"usr/share/doc/${P}/freecad.qhc.ecompress.skip
 138         >> "${ED}"usr/share/doc/${P}/freecad.qch.ecompress.skip
 139
 140         python_optimize "${ED}"usr/{$(get_libdir),share}/${P}/Mod/
 141 }