media-gfx/fotowall/fotowall-1.0.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit qmake-utils
   7
   8 DESCRIPTION="Qt5 tool for creating wallpapers"
   9 HOMEPAGE="https://www.enricoros.com/opensource/fotowall/"
  10 SRC_URI="https://github.com/enricoros/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
  11
  12 LICENSE="GPL-2+"
  13 SLOT="0"
  14 KEYWORDS="amd64 x86"
  15 IUSE="opengl webcam"
  16
  17 RDEPEND="
  18         dev-qt/qtcore:5
  19         dev-qt/qtgui:5
  20         dev-qt/qtnetwork:5
  21         dev-qt/qtprintsupport:5
  22         dev-qt/qtsvg:5
  23         dev-qt/qtwidgets:5
  24         dev-qt/qtxml:5
  25         opengl? ( dev-qt/qtopengl:5 )
  26 "
  27 DEPEND="${RDEPEND}
  28         webcam? ( media-libs/libv4l )
  29 "
  30
  31 PATCHES=(
  32         "${FILESDIR}/${P}-qt-5.11.patch"
  33         "${FILESDIR}/${P}-qt-5.15.patch"
  34 )
  35
  36 src_prepare() {
  37         default
  38
  39         sed -i -e "s|linux/videodev.h|libv4l1-videodev.h|" \
  40                 3rdparty/videocapture/VideoDevice.h || die
  41
  42         if ! use opengl; then
  43                 sed -i "/QT += opengl/d" ${PN}.pro || die
  44         fi
  45 }
  46
  47 src_configure() {
  48         if ! use webcam; then
  49                 eqmake5 ${PN}.pro "CONFIG+=no-webcam"
  50         else
  51                 eqmake5
  52         fi
  53 }
  54
  55 src_install() {
  56         emake INSTALL_ROOT="${D}" install
  57         dodoc README.markdown
  58 }