media-gfx/fbida/fbida-2.13-r1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 inherit eutils toolchain-funcs
   6
   7 DESCRIPTION="Image viewers for the framebuffer console (fbi) and X11 (ida)"
   8 HOMEPAGE="https://www.kraxel.org/blog/linux/fbida/"
   9 SRC_URI="
  10         https://www.kraxel.org/releases/${PN}/${P}.tar.gz
  11         mirror://gentoo/ida.png.bz2
  12 "
  13 LICENSE="GPL-2 IJG"
  14 SLOT="0"
  15 KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ppc ~ppc64 ~sparc ~x86"
  16 IUSE="curl fbcon ghostscript +gif lirc +png scanner +tiff X +webp"
  17 REQUIRED_USE="
  18         ghostscript? ( tiff )
  19 "
  20
  21 CDEPEND="
  22         !media-gfx/fbi
  23         app-text/poppler
  24         >=media-libs/fontconfig-2.2
  25         >=media-libs/freetype-2.0
  26         media-libs/libepoxy
  27         media-libs/libexif
  28         media-libs/mesa[X(+)]
  29         virtual/jpeg:*
  30         virtual/ttf-fonts
  31         x11-libs/cairo[opengl]
  32         x11-libs/libdrm
  33         curl? ( net-misc/curl )
  34         gif? ( media-libs/giflib:= )
  35         lirc? ( app-misc/lirc )
  36         png? ( media-libs/libpng:* )
  37         scanner? ( media-gfx/sane-backends )
  38         tiff? ( media-libs/tiff:* )
  39         webp? ( media-libs/libwebp )
  40         X? (
  41                 >=x11-libs/motif-2.3:0
  42                 x11-libs/libX11
  43                 x11-libs/libXpm
  44                 x11-libs/libXt
  45         )
  46 "
  47
  48 DEPEND="
  49         ${CDEPEND}
  50         X? ( x11-base/xorg-proto )
  51 "
  52
  53 RDEPEND="
  54         ${CDEPEND}
  55         ghostscript? (
  56                 app-text/ghostscript-gpl
  57         )
  58 "
  59 PATCHES=(
  60         "${FILESDIR}"/ida-desktop.patch
  61         "${FILESDIR}"/${PN}-2.10-giflib-4.2.patch
  62         "${FILESDIR}"/${PN}-2.10-fprintf-format.patch
  63         "${FILESDIR}"/${PN}-2.13-Autoconf.patch
  64 )
  65
  66 src_configure() {
  67         tc-export CC CPP
  68
  69         # Let autoconf do its job and then fix things to build fbida
  70         # according to our specifications
  71         emake Make.config
  72
  73         gentoo_fbida() {
  74                 local useflag=${1}
  75                 local config=${2}
  76
  77                 local option="no"
  78                 use ${useflag} && option="yes"
  79
  80                 sed -i \
  81                         -e "s|HAVE_${config}.*|HAVE_${config} := ${option}|" \
  82                         "${S}/Make.config" || die
  83         }
  84
  85         gentoo_fbida X MOTIF
  86         gentoo_fbida curl LIBCURL
  87         gentoo_fbida fbcon LINUX_FB_H
  88         gentoo_fbida gif LIBUNGIF
  89         gentoo_fbida lirc LIBLIRC
  90         gentoo_fbida ghostscript LIBTIFF
  91         gentoo_fbida png LIBPNG
  92         gentoo_fbida scanner LIBSANE
  93         gentoo_fbida tiff LIBTIFF
  94         gentoo_fbida webp LIBWEBP
  95 }
  96
  97 src_compile() {
  98         emake verbose=yes
  99 }
 100
 101 src_install() {
 102         emake \
 103                 DESTDIR="${ED}" \
 104                 STRIP="" \
 105                 prefix=/usr \
 106                 install
 107
 108         dodoc README
 109
 110         if use fbcon && ! use ghostscript; then
 111                 rm \
 112                         "${ED}"/usr/bin/fbgs \
 113                         "${ED}"/usr/share/man/man1/fbgs.1 \
 114                         || die
 115         fi
 116
 117         if use X ; then
 118                 doicon "${WORKDIR}"/ida.png
 119                 domenu desktop/ida.desktop
 120         fi
 121 }