media-gfx/fbida/fbida-2.09-r4.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6 inherit eutils toolchain-funcs
   7
   8 DESCRIPTION="Image viewers for the framebuffer console (fbi) and X11 (ida)"
   9 HOMEPAGE="http://www.kraxel.org/blog/linux/fbida/"
  10 SRC_URI="
  11         http://www.kraxel.org/releases/${PN}/${P}.tar.gz
  12         https://dev.gentoo.org/~jer/${P}-jpeg-9a.patch.bz2
  13         mirror://gentoo/ida.png.bz2
  14 "
  15 LICENSE="GPL-2 IJG"
  16 SLOT="0"
  17 KEYWORDS="alpha amd64 arm hppa ppc ppc64 ~sh sparc x86"
  18 IUSE="curl fbcon +gif lirc pdf +png scanner +tiff X +webp"
  19 REQUIRED_USE="
  20         pdf? ( tiff )
  21 "
  22
  23 RDEPEND="
  24         !media-gfx/fbi
  25         >=media-libs/fontconfig-2.2
  26         >=media-libs/freetype-2.0
  27         media-libs/libexif
  28         curl? ( net-misc/curl )
  29         gif? ( media-libs/giflib:= )
  30         lirc? ( app-misc/lirc )
  31         png? ( media-libs/libpng )
  32         scanner? ( media-gfx/sane-backends )
  33         tiff? ( media-libs/tiff )
  34         virtual/jpeg
  35         virtual/ttf-fonts
  36         webp? ( media-libs/libwebp )
  37         X? (
  38                 >=x11-libs/motif-2.3:0
  39                 x11-libs/libX11
  40                 x11-libs/libXpm
  41                 x11-libs/libXt
  42         )
  43 "
  44
  45 DEPEND="
  46         ${RDEPEND}
  47         X? ( x11-proto/xextproto x11-proto/xproto )
  48         pdf? ( app-text/ghostscript-gpl )
  49 "
  50
  51 src_prepare() {
  52         epatch "${FILESDIR}"/ida-desktop.patch
  53         epatch "${FILESDIR}"/${P}-make.patch
  54         epatch "${FILESDIR}"/${P}-giflib.patch
  55
  56         pushd jpeg/ >/dev/null
  57         epatch -p2 "${WORKDIR}"/${P}-jpeg-9a.patch
  58         popd >/dev/null
  59
  60         sed -i \
  61                 -e 's:DGifOpenFileName,ungif:DGifOpenFileName,gif:' \
  62                 -e 's:-lungif:-lgif:' \
  63                 "${S}"/GNUmakefile || die
  64
  65         if [[ $(gcc-major-version) -lt 4 ]]; then
  66                 sed      -i-e 's:-Wno-pointer-sign::' "${S}"/GNUmakefile || die
  67         fi
  68
  69         tc-export CC CPP
  70 }
  71
  72 src_configure() {
  73         # Let autoconf do its job and then fix things to build fbida
  74         # according to our specifications
  75         emake Make.config
  76
  77         gentoo_fbida() {
  78                 local useflag=${1}
  79                 local config=${2}
  80
  81                 local option="no"
  82                 use ${useflag} && option="yes"
  83
  84                 sed -i \
  85                         -e "s|HAVE_${config}.*|HAVE_${config} := ${option}|" \
  86                         "${S}/Make.config" || die
  87         }
  88
  89         gentoo_fbida X MOTIF
  90         gentoo_fbida curl LIBCURL
  91         gentoo_fbida fbcon LINUX_FB_H
  92         gentoo_fbida gif LIBUNGIF
  93         gentoo_fbida lirc LIBLIRC
  94         gentoo_fbida pdf LIBTIFF
  95         gentoo_fbida png LIBPNG
  96         gentoo_fbida scanner LIBSANE
  97         gentoo_fbida tiff LIBTIFF
  98         gentoo_fbida webp LIBWEBP
  99 }
 100
 101 src_compile() {
 102         emake verbose=yes
 103 }
 104
 105 src_install() {
 106         emake \
 107                 DESTDIR="${D}" \
 108                 STRIP="" \
 109                 prefix=/usr \
 110                 install
 111
 112         dodoc README
 113
 114         if use fbcon && ! use pdf; then
 115                 rm "${D}"/usr/bin/fbgs "${D}"/usr/share/man/man1/fbgs.1 || die
 116         fi
 117
 118         if use X ; then
 119                 doicon "${WORKDIR}"/ida.png
 120                 domenu desktop/ida.desktop
 121         fi
 122 }