media-gfx/eog-plugins/eog-plugins-3.16.2.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI="5"
   6 GCONF_DEBUG="no"
   7 GNOME2_LA_PUNT="yes"
   8 PYTHON_COMPAT=( python{3_3,3_4} )
   9
  10 inherit gnome2 python-r1
  11
  12 DESCRIPTION="Eye of GNOME plugins"
  13 HOMEPAGE="https://wiki.gnome.org/Apps/EyeOfGnome/Plugins"
  14
  15 LICENSE="GPL-2"
  16 SLOT="0"
  17 KEYWORDS="amd64 x86"
  18
  19 IUSE="+exif +flickr map +picasa +python"
  20 REQUIRED_USE="
  21         map? ( exif )
  22         python? ( ^^ ( $(python_gen_useflags '*') ) )"
  23
  24 RDEPEND="
  25         >=dev-libs/glib-2.38:2
  26         >=dev-libs/libpeas-0.7.4:=
  27         >=media-gfx/eog-3.15.90
  28         >=x11-libs/gtk+-3.14:3
  29         exif? ( >=media-libs/libexif-0.6.16 )
  30         flickr? ( media-gfx/postr )
  31         map? (
  32                 media-libs/libchamplain:0.12[gtk]
  33                 >=media-libs/clutter-1.9.4:1.0
  34                 >=media-libs/clutter-gtk-1.1.2:1.0 )
  35         picasa? ( >=dev-libs/libgdata-0.9.1:= )
  36         python? (
  37                 ${PYTHON_DEPS}
  38                 >=dev-libs/glib-2.32:2[dbus]
  39                 dev-libs/libpeas:=[gtk,python,${PYTHON_USEDEP}]
  40                 dev-python/pygobject:3[${PYTHON_USEDEP}]
  41                 gnome-base/gsettings-desktop-schemas
  42                 media-gfx/eog[introspection]
  43                 x11-libs/gtk+:3[introspection]
  44                 x11-libs/pango[introspection] )
  45 "
  46 DEPEND="${RDEPEND}
  47         >=dev-util/intltool-0.50.1
  48         sys-devel/gettext
  49         virtual/pkgconfig
  50 "
  51
  52 pkg_setup() {
  53         use python && [[ ${MERGE_TYPE} != binary ]] && python_setup
  54 }
  55
  56 src_configure() {
  57         local plugins="fit-to-width,send-by-mail,hide-titlebar,light-theme"
  58         use exif && plugins="${plugins},exif-display"
  59         use flickr && plugins="${plugins},postr"
  60         use map && plugins="${plugins},map"
  61         use picasa && plugins="${plugins},postasa"
  62         use python && plugins="${plugins},slideshowshuffle,pythonconsole,fullscreenbg,export-to-folder,maximize-windows"
  63         gnome2_src_configure \
  64                 $(use_enable python) \
  65                 --with-plugins=${plugins}
  66 }