media-gfx/digikam/digikam-7.0.0_beta3.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 KFMIN=5.60.0
   7 QTMIN=5.12.3
   8 inherit ecm kde.org toolchain-funcs
   9
  10 if [[ ${KDE_BUILD_TYPE} != live ]]; then
  11         MY_PV=${PV/_/-}
  12         MY_P=${PN}-${MY_PV}
  13         if [[ ${PV} =~ beta[0-9]$ ]]; then
  14                 SRC_URI="mirror://kde/unstable/${PN}/"
  15         else
  16                 SRC_URI="mirror://kde/unstable/${PN}/${PV}/"
  17         fi
  18         SRC_URI+="${MY_P}.tar.xz"
  19         KEYWORDS="~amd64 ~x86"
  20         S="${WORKDIR}/${MY_P}"
  21 fi
  22
  23 DESCRIPTION="Digital photo management application"
  24 HOMEPAGE="https://www.digikam.org/"
  25
  26 LICENSE="GPL-2"
  27 SLOT="5"
  28 IUSE="addressbook calendar gphoto2 heif +imagemagick +lensfun marble mediaplayer mysql opengl openmp +panorama scanner semantic-desktop vkontakte webkit X"
  29
  30 BDEPEND="
  31         >=dev-util/cmake-3.14.3
  32         sys-devel/gettext
  33         panorama? (
  34                 sys-devel/bison
  35                 sys-devel/flex
  36         )
  37 "
  38 COMMON_DEPEND="
  39         dev-libs/expat
  40         >=dev-qt/qtconcurrent-${QTMIN}:5
  41         >=dev-qt/qtdbus-${QTMIN}:5
  42         >=dev-qt/qtgui-${QTMIN}:5[-gles2-only]
  43         >=dev-qt/qtnetwork-${QTMIN}:5
  44         >=dev-qt/qtprintsupport-${QTMIN}:5
  45         >=dev-qt/qtsql-${QTMIN}:5[mysql?]
  46         >=dev-qt/qtwidgets-${QTMIN}:5
  47         >=dev-qt/qtxml-${QTMIN}:5
  48         >=dev-qt/qtxmlpatterns-${QTMIN}:5
  49         >=kde-frameworks/kconfig-${KFMIN}:5
  50         >=kde-frameworks/kconfigwidgets-${KFMIN}:5
  51         >=kde-frameworks/kcoreaddons-${KFMIN}:5
  52         >=kde-frameworks/ki18n-${KFMIN}:5
  53         >=kde-frameworks/kiconthemes-${KFMIN}:5
  54         >=kde-frameworks/kio-${KFMIN}:5
  55         >=kde-frameworks/knotifications-${KFMIN}:5
  56         >=kde-frameworks/knotifyconfig-${KFMIN}:5
  57         >=kde-frameworks/kservice-${KFMIN}:5
  58         >=kde-frameworks/kwidgetsaddons-${KFMIN}:5
  59         >=kde-frameworks/kwindowsystem-${KFMIN}:5
  60         >=kde-frameworks/kxmlgui-${KFMIN}:5
  61         >=kde-frameworks/solid-${KFMIN}:5
  62         >=media-gfx/exiv2-0.27:=
  63         media-libs/lcms:2
  64         media-libs/liblqr
  65         media-libs/libpng:0=
  66         >=media-libs/opencv-3.3.0:=[contrib,contribdnn]
  67         media-libs/tiff:0
  68         virtual/jpeg:0
  69         addressbook? (
  70                 >=kde-apps/akonadi-contacts-19.04.3:5
  71                 >=kde-frameworks/kcontacts-${KFMIN}:5
  72         )
  73         calendar? ( >=kde-frameworks/kcalendarcore-${KFMIN}:5 )
  74         gphoto2? ( media-libs/libgphoto2:= )
  75         heif? ( media-libs/x265:= )
  76         imagemagick? ( media-gfx/imagemagick:= )
  77         lensfun? ( media-libs/lensfun )
  78         marble? (
  79                 >=dev-qt/qtconcurrent-${QTMIN}:5
  80                 >=kde-apps/marble-19.04.3:5
  81                 >=kde-frameworks/kbookmarks-${KFMIN}:5
  82         )
  83         mediaplayer? (
  84                 media-libs/qtav[opengl]
  85                 media-video/ffmpeg:=
  86         )
  87         opengl? (
  88                 >=dev-qt/qtopengl-${QTMIN}:5
  89                 virtual/opengl
  90         )
  91         panorama? ( >=kde-frameworks/threadweaver-${KFMIN}:5 )
  92         scanner? ( >=kde-apps/libksane-19.04.3:5 )
  93         semantic-desktop? ( >=kde-frameworks/kfilemetadata-${KFMIN}:5 )
  94         vkontakte? ( net-libs/libkvkontakte:5 )
  95         !webkit? ( >=dev-qt/qtwebengine-${QTMIN}:5[widgets] )
  96         webkit? ( >=dev-qt/qtwebkit-5.212.0_pre20180120:5 )
  97         X? (
  98                 >=dev-qt/qtx11extras-${QTMIN}:5
  99                 x11-libs/libX11
 100         )
 101 "
 102 DEPEND="${COMMON_DEPEND}
 103         dev-cpp/eigen:3
 104         dev-libs/boost[threads]
 105 "
 106 RDEPEND="${COMMON_DEPEND}
 107         mysql? ( virtual/mysql[server(+)] )
 108         panorama? ( media-gfx/hugin )
 109 "
 110
 111 PATCHES=( "${FILESDIR}"/${P}-qt-5.15.patch )
 112
 113 RESTRICT+=" test"
 114 # bug 366505
 115
 116 pkg_pretend() {
 117         [[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
 118         ecm_pkg_pretend
 119 }
 120
 121 pkg_setup() {
 122         [[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
 123         ecm_pkg_setup
 124 }
 125
 126 # FIXME: Unbundle libraw (libs/rawengine/libraw)
 127 src_configure() {
 128         local mycmakeargs=(
 129                 -DBUILD_TESTING=OFF # bug 698192
 130                 -DENABLE_APPSTYLES=ON
 131                 -DCMAKE_DISABLE_FIND_PACKAGE_Jasper=ON
 132                 -DENABLE_AKONADICONTACTSUPPORT=$(usex addressbook)
 133                 $(cmake_use_find_package calendar KF5CalendarCore)
 134                 $(cmake_use_find_package gphoto2 Gphoto2)
 135                 $(cmake_use_find_package heif X265)
 136                 $(cmake_use_find_package imagemagick ImageMagick)
 137                 $(cmake_use_find_package lensfun LensFun)
 138                 $(cmake_use_find_package marble Marble)
 139                 -DENABLE_MEDIAPLAYER=$(usex mediaplayer)
 140                 $(cmake_use_find_package mediaplayer QtAV)
 141                 -DENABLE_MYSQLSUPPORT=$(usex mysql)
 142                 -DENABLE_INTERNALMYSQL=$(usex mysql)
 143                 $(cmake_use_find_package opengl OpenGL)
 144                 $(cmake_use_find_package panorama KF5ThreadWeaver)
 145                 $(cmake_use_find_package scanner KF5Sane)
 146                 $(cmake_use_find_package semantic-desktop KF5FileMetaData)
 147                 $(cmake_use_find_package vkontakte KF5Vkontakte)
 148                 -DENABLE_QWEBENGINE=$(usex !webkit)
 149                 $(cmake_use_find_package X X11)
 150         )
 151
 152         ecm_src_configure
 153 }