media-gfx/digikam/digikam-5.3.0-r1.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=6
   6
   7 if [[ ${KDE_BUILD_TYPE} != live ]]; then
   8         KDE_HANDBOOK="true"
   9         KDE_TEST="true"
  10 fi
  11 CMAKE_MAKEFILE_GENERATOR="emake"
  12 inherit kde5 toolchain-funcs
  13
  14 DESCRIPTION="Digital photo management application"
  15 HOMEPAGE="https://www.digikam.org/"
  16
  17 LICENSE="GPL-2"
  18 KEYWORDS="amd64 ~x86"
  19 IUSE="addressbook calendar gphoto2 jpeg2k +kipi +lensfun marble semantic-desktop mysql opengl openmp +panorama scanner video X"
  20
  21 if [[ ${KDE_BUILD_TYPE} != live ]]; then
  22         MY_PV=${PV/_/-}
  23         MY_P=${PN}-${MY_PV}
  24         SRC_BRANCH=stable
  25         [[ ${PV} =~ beta[0-9]$ ]] && SRC_BRANCH=unstable
  26         SRC_URI="mirror://kde/${SRC_BRANCH}/digikam/${MY_P}.tar.xz"
  27         S="${WORKDIR}/${MY_P}/core"
  28 fi
  29
  30 COMMON_DEPEND="
  31         $(add_frameworks_dep kconfig)
  32         $(add_frameworks_dep kconfigwidgets)
  33         $(add_frameworks_dep kcoreaddons)
  34         $(add_frameworks_dep kiconthemes)
  35         $(add_frameworks_dep ki18n)
  36         $(add_frameworks_dep kio)
  37         $(add_frameworks_dep knotifications)
  38         $(add_frameworks_dep knotifyconfig)
  39         $(add_frameworks_dep kservice)
  40         $(add_frameworks_dep kwidgetsaddons)
  41         $(add_frameworks_dep kwindowsystem)
  42         $(add_frameworks_dep kxmlgui)
  43         $(add_frameworks_dep solid)
  44         $(add_qt_dep qtdbus)
  45         $(add_qt_dep qtgui '-gles2')
  46         $(add_qt_dep qtprintsupport)
  47         $(add_qt_dep qtsql 'mysql?')
  48         $(add_qt_dep qtwebkit)
  49         $(add_qt_dep qtwidgets)
  50         $(add_qt_dep qtxml)
  51         dev-libs/expat
  52         media-gfx/exiv2:=
  53         media-libs/lcms:2
  54         media-libs/liblqr
  55         >=media-libs/libpgf-6.12.27
  56         media-libs/libpng:0=
  57         media-libs/opencv:=[-qt4(-)]
  58         || ( <media-libs/opencv-3.0.0 >=media-libs/opencv-3.1.0 )
  59         media-libs/tiff:0
  60         virtual/jpeg:0
  61         addressbook? (
  62                 $(add_kdeapps_dep akonadi-contacts)
  63                 $(add_kdeapps_dep kcontacts)
  64         )
  65         calendar? ( $(add_kdeapps_dep kcalcore) )
  66         gphoto2? ( media-libs/libgphoto2:= )
  67         jpeg2k? ( media-libs/jasper:= )
  68         kipi? ( $(add_kdeapps_dep libkipi '' '16.03.80') )
  69         lensfun? ( media-libs/lensfun )
  70         marble? (
  71                 $(add_frameworks_dep kbookmarks)
  72                 $(add_kdeapps_dep marble)
  73                 $(add_qt_dep qtconcurrent)
  74                 $(add_qt_dep qtnetwork)
  75         )
  76         mysql? ( virtual/mysql )
  77         opengl? (
  78                 $(add_qt_dep qtopengl)
  79                 virtual/opengl
  80         )
  81         panorama? ( $(add_frameworks_dep threadweaver) )
  82         scanner? ( $(add_kdeapps_dep libksane) )
  83         semantic-desktop? ( $(add_frameworks_dep kfilemetadata) )
  84         video? ( $(add_qt_dep qtmultimedia 'widgets') )
  85         X? (
  86                 $(add_qt_dep qtx11extras)
  87                 x11-libs/libX11
  88         )
  89 "
  90 DEPEND="${COMMON_DEPEND}
  91         $(add_qt_dep qtconcurrent)
  92         dev-cpp/eigen:3
  93         dev-libs/boost[threads]
  94         sys-devel/gettext
  95         panorama? (
  96                 sys-devel/bison
  97                 sys-devel/flex
  98         )
  99 "
 100 RDEPEND="${COMMON_DEPEND}
 101         media-plugins/kipi-plugins:5
 102         panorama? ( media-gfx/hugin )
 103         !media-gfx/digikam:4
 104 "
 105
 106 RESTRICT=test
 107 # bug 366505
 108
 109 PATCHES=( "${FILESDIR}/${P}-db-lock.patch" )
 110
 111 pkg_pretend() {
 112         [[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
 113         kde5_pkg_pretend
 114 }
 115
 116 pkg_setup() {
 117         [[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
 118         kde5_pkg_setup
 119 }
 120
 121 # FIXME: Unbundle libraw (libs/rawengine/libraw)
 122 src_prepare() {
 123         if [[ ${KDE_BUILD_TYPE} != live ]]; then
 124                 # prepare the translations
 125                 mv "${WORKDIR}/${MY_P}/po" po || die
 126                 find po -name "*.po" -and -not -name "digikam.po" -delete || die
 127                 echo "set_property(GLOBAL PROPERTY ALLOW_DUPLICATE_CUSTOM_TARGETS 1)" >> CMakeLists.txt || die
 128                 echo "find_package(Gettext REQUIRED)" >> CMakeLists.txt || die
 129                 echo "add_subdirectory( po )" >> CMakeLists.txt || die
 130
 131                 if use handbook; then
 132                         # subdirs need to be preserved b/c relative paths...
 133                         # doc-translated is, in fact, broken, and ignored
 134                         mv "${WORKDIR}/${MY_P}/doc/${PN}" doc-default || die
 135                         echo "find_package(KF5DocTools REQUIRED)" >> CMakeLists.txt || die
 136                         echo "add_subdirectory( doc-default )" >> CMakeLists.txt || die
 137                 fi
 138         fi
 139
 140         if ! use marble; then
 141                 punt_bogus_dep Qt5 Network
 142         fi
 143
 144         kde5_src_prepare
 145 }
 146
 147 src_configure() {
 148         local mycmakeargs=(
 149                 -DENABLE_APPSTYLES=ON
 150                 -DENABLE_AKONADICONTACTSUPPORT=$(usex addressbook)
 151                 -DENABLE_MYSQLSUPPORT=$(usex mysql)
 152                 -DENABLE_MEDIAPLAYER=$(usex video)
 153                 -DENABLE_OPENCV3=$(has_version ">=media-libs/opencv-3" && echo yes || echo no)
 154                 $(cmake-utils_use_find_package calendar KF5CalendarCore)
 155                 $(cmake-utils_use_find_package gphoto2 Gphoto2)
 156                 $(cmake-utils_use_find_package jpeg2k Jasper)
 157                 $(cmake-utils_use_find_package kipi KF5Kipi)
 158                 $(cmake-utils_use_find_package lensfun LensFun)
 159                 $(cmake-utils_use_find_package marble Marble)
 160                 $(cmake-utils_use_find_package opengl OpenGL)
 161                 $(cmake-utils_use_find_package openmp OpenMP)
 162                 $(cmake-utils_use_find_package panorama KF5ThreadWeaver)
 163                 $(cmake-utils_use_find_package scanner KF5Sane)
 164                 $(cmake-utils_use_find_package semantic-desktop KF5FileMetaData)
 165                 $(cmake-utils_use_find_package X X11)
 166         )
 167
 168         kde5_src_configure
 169 }