media-gfx/digikam/digikam-5.0.0.ebuild

   1 # Copyright 1999-2016 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=6
   6
   7 if [[ ${KDE_BUILD_TYPE} != live ]]; then
   8         KDE_TEST=true
   9 fi
  10 CMAKE_MAKEFILE_GENERATOR="emake"
  11 inherit kde5
  12
  13 DESCRIPTION="Digital photo management application"
  14 HOMEPAGE="https://www.digikam.org/"
  15
  16 LICENSE="GPL-2"
  17 KEYWORDS="~amd64 ~x86"
  18 IUSE="addressbook gphoto2 kipi lensfun marble semantic-desktop mysql scanner video X"
  19
  20 if [[ ${KDE_BUILD_TYPE} != live ]]; then
  21
  22         MY_PV=${PV/_/-}
  23         MY_P=${PN}-${MY_PV}
  24
  25         SRC_BRANCH=stable
  26         [[ ${PV} =~ beta[0-9]$ ]] && SRC_BRANCH=unstable
  27         SRC_URI="mirror://kde/${SRC_BRANCH}/digikam/${MY_P}.tar.xz"
  28
  29         S="${WORKDIR}/${MY_P}/core"
  30
  31 fi
  32
  33 COMMON_DEPEND="
  34         $(add_frameworks_dep kcompletion)
  35         $(add_frameworks_dep kconfig)
  36         $(add_frameworks_dep kconfigwidgets)
  37         $(add_frameworks_dep kcoreaddons)
  38         $(add_frameworks_dep kiconthemes)
  39         $(add_frameworks_dep ki18n)
  40         $(add_frameworks_dep kio)
  41         $(add_frameworks_dep kjobwidgets)
  42         $(add_frameworks_dep knotifications)
  43         $(add_frameworks_dep knotifyconfig)
  44         $(add_frameworks_dep kservice)
  45         $(add_frameworks_dep ktextwidgets)
  46         $(add_frameworks_dep kwidgetsaddons)
  47         $(add_frameworks_dep kwindowsystem)
  48         $(add_frameworks_dep kxmlgui)
  49         $(add_frameworks_dep solid)
  50         $(add_kdeapps_dep libkexiv2)
  51         $(add_qt_dep qtconcurrent)
  52         $(add_qt_dep qtdbus)
  53         $(add_qt_dep qtgui)
  54         $(add_qt_dep qtprintsupport)
  55         $(add_qt_dep qtscript)
  56         $(add_qt_dep qtsql 'mysql?')
  57         $(add_qt_dep qtwebkit)
  58         $(add_qt_dep qtwidgets)
  59         $(add_qt_dep qtxml)
  60         dev-libs/boost[threads]
  61         dev-libs/expat
  62         >=media-gfx/exiv2-0.24:=
  63         media-libs/jasper
  64         media-libs/lcms:2
  65         media-libs/liblqr
  66         >=media-libs/libpgf-6.12.27
  67         media-libs/libpng:0=
  68         >=media-libs/opencv-3.0.0:=
  69         media-libs/tiff:0
  70         virtual/jpeg:0
  71         addressbook? (
  72                 $(add_kdeapps_dep akonadi-contact)
  73                 $(add_kdeapps_dep kcontacts)
  74         )
  75         scanner? ( $(add_kdeapps_dep libksane) )
  76         gphoto2? ( media-libs/libgphoto2:= )
  77         kipi? ( $(add_kdeapps_dep libkipi '' '16.03.80') )
  78         lensfun? ( media-libs/lensfun )
  79         marble? (
  80                 $(add_frameworks_dep kbookmarks)
  81                 $(add_frameworks_dep kitemmodels)
  82                 $(add_kdeapps_dep marble)
  83         )
  84         semantic-desktop? ( $(add_frameworks_dep kfilemetadata) )
  85         mysql? ( virtual/mysql )
  86         video? ( $(add_qt_dep qtmultimedia 'widgets') )
  87         X? (
  88                 $(add_qt_dep qtx11extras)
  89                 x11-libs/libX11
  90         )
  91 "
  92 DEPEND="${COMMON_DEPEND}
  93         dev-cpp/eigen:3
  94         sys-devel/gettext
  95 "
  96 RDEPEND="${COMMON_DEPEND}
  97         media-plugins/kipi-plugins:5
  98         !media-gfx/digikam:4
  99 "
 100
 101 RESTRICT=test
 102 # bug 366505
 103
 104 src_prepare() {
 105         undetect_lib() {
 106                 local _use=${1}
 107                 local _name=${2}
 108                 [[ -z ${_name} ]] && _name=$(echo ${_use} | sed 's/./\U&/g')
 109                 use $_use || \
 110                         sed -i -e "/DETECT_LIB${_name}/d" CMakeLists.txt || die
 111         }
 112
 113         undetect_lib kipi
 114         undetect_lib scanner KSANE
 115
 116         kde5_src_prepare
 117 }
 118
 119 src_configure() {
 120         # LQR = only allows to choose between bundled/external
 121         local mycmakeargs=(
 122                 -DENABLE_OPENCV3=ON
 123                 -DENABLE_AKONADICONTACTSUPPORT=$(usex addressbook)
 124                 -DENABLE_KFILEMETADATASUPPORT=$(usex semantic-desktop)
 125                 -DENABLE_MYSQLSUPPORT=$(usex mysql)
 126                 -DENABLE_MEDIAPLAYER=$(usex video)
 127                 $(cmake-utils_use_find_package gphoto2 Gphoto2)
 128                 $(cmake-utils_use_find_package lensfun LensFun)
 129                 $(cmake-utils_use_find_package marble Marble)
 130                 $(cmake-utils_use_find_package X X11)
 131         )
 132
 133         kde5_src_configure
 134 }