media-gfx/cura/cura-3.4.1.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 PYTHON_COMPAT=( python3_{5,6} )
   7 inherit cmake-utils fdo-mime gnome2-utils python-single-r1
   8
   9 MY_PN=Cura
  10
  11 DESCRIPTION="A 3D model slicing application for 3D printing"
  12 HOMEPAGE="https://github.com/Ultimaker/Cura"
  13 SRC_URI="https://github.com/Ultimaker/${MY_PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
  14
  15 LICENSE="LGPL-3"
  16 SLOT="0"
  17 KEYWORDS="~amd64 ~x86"
  18 IUSE="+usb zeroconf"
  19 REQUIRED_USE="${PYTHON_REQUIRED_USE}"
  20
  21 RDEPEND="${PYTHON_DEPS}
  22         >=dev-python/uranium-${PV:0:3}[${PYTHON_USEDEP}]
  23         >=media-gfx/curaengine-${PV:0:3}
  24         >=media-gfx/fdm-materials-${PV:0:3}
  25         >=dev-libs/libsavitar-${PV:0:3}:=[python,${PYTHON_USEDEP}]
  26         >=dev-libs/libcharon-${PV:0:3}[${PYTHON_USEDEP}]
  27         usb? ( dev-python/pyserial[${PYTHON_USEDEP}] )
  28         zeroconf? ( dev-python/zeroconf[${PYTHON_USEDEP}] )"
  29
  30 DEPEND="${RDEPEND}
  31         sys-devel/gettext"
  32
  33 S="${WORKDIR}/${MY_PN}-${PV}"
  34 PATCHES=( "${FILESDIR}/${PN}-3.3.0-fix-install-paths.patch" )
  35 DOCS=( README.md )
  36
  37 src_prepare() {
  38         default
  39         sed -i "s/set(CURA_VERSION \"master\"/set(CURA_VERSION \"${PV}\"/" CMakeLists.txt || die
  40 }
  41
  42 src_configure() {
  43         local mycmakeargs=(
  44                 -DPYTHON_SITE_PACKAGES_DIR="$(python_get_sitedir)"
  45         )
  46         cmake-utils_src_configure
  47 }
  48
  49 src_compile() {
  50         cmake-utils_src_compile
  51 }
  52
  53 src_install() {
  54         cmake-utils_src_install
  55         doicon icons/*.png
  56         python_optimize "${D}${get_libdir}"
  57 }
  58
  59 pkg_preinst() {
  60         gnome2_icon_savelist
  61 }
  62
  63 pkg_postinst() {
  64         fdo-mime_desktop_database_update
  65         fdo-mime_mime_database_update
  66         gnome2_icon_cache_update
  67 }
  68
  69 pkg_postrm() {
  70         fdo-mime_desktop_database_update
  71         fdo-mime_mime_database_update
  72         gnome2_icon_cache_update
  73 }