media-gfx/colorhug-client/colorhug-client-0.2.5.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6 GCONF_DEBUG="no"
   7
   8 inherit bash-completion-r1 eutils gnome2
   9
  10 DESCRIPTION="Client tools for the ColorHug display colorimeter"
  11 HOMEPAGE="http://www.hughski.com/"
  12 SRC_URI="http://people.freedesktop.org/~hughsient/releases/${P}.tar.xz"
  13
  14 LICENSE="GPL-2"
  15 SLOT="0"
  16 KEYWORDS="amd64 x86"
  17 IUSE=""
  18
  19 RDEPEND="
  20         dev-db/sqlite:3
  21         >=dev-libs/glib-2.31.10:2
  22         >=dev-libs/libgusb-0.2.2
  23         media-libs/lcms:2
  24         >=media-libs/libcanberra-0.10[gtk3]
  25         net-libs/libsoup:2.4
  26         >=x11-libs/gtk+-3.11.2:3
  27         >=x11-misc/colord-1.2.6:0=
  28         >=x11-libs/colord-gtk-0.1.24
  29 "
  30 DEPEND="${RDEPEND}
  31         app-text/docbook-sgml-dtd:4.1
  32         app-text/docbook-sgml-utils
  33         app-text/yelp-tools
  34         >=dev-util/intltool-0.50
  35         >=sys-devel/gettext-0.17
  36         virtual/pkgconfig
  37 "
  38 # docbook stuff needed for man pages
  39
  40 src_prepare() {
  41         # Fix .desktop
  42         sed -e '/Terminal=/ d' -i data/colorhug-docs.desktop || die
  43
  44         gnome2_src_prepare
  45 }
  46
  47 src_configure() {
  48         # introspection checked but not needed by anything
  49         gnome2_src_configure --disable-introspection
  50 }
  51
  52 src_install() {
  53         gnome2_src_install bashcompletiondir="$(get_bashcompdir)"
  54 }