media-fonts/unifont/unifont-13.0.01.ebuild

   1 # Copyright 2003-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit font toolchain-funcs
   7
   8 DESCRIPTION="GNU Unifont - a Pan-Unicode X11 bitmap iso10646 font"
   9 HOMEPAGE="http://unifoundry.com/"
  10 SRC_URI="mirror://gnu/${PN}/${P}/${P}.tar.gz"
  11
  12 LICENSE="GPL-2"
  13 SLOT="0"
  14 KEYWORDS="~alpha amd64 arm ~ia64 ppc ppc64 ~s390 sparc x86"
  15 IUSE="fontforge utils"
  16
  17 BDEPEND="
  18         fontforge? (
  19                 app-text/bdf2psf
  20                 dev-lang/perl
  21                 dev-perl/GD[png(-)]
  22                 media-gfx/fontforge
  23                 x11-apps/bdftopcf
  24         )
  25 "
  26 RDEPEND="
  27         utils? (
  28                 dev-lang/perl
  29                 dev-perl/GD[png(-)]
  30         )
  31 "
  32
  33 PATCHES=(
  34         "${FILESDIR}"/11.0.02-make.patch
  35 )
  36
  37 src_compile() {
  38         buildargs=(
  39                 BUILDFONT=$(usex fontforge 1 '')
  40                 CC="$(tc-getCC)"
  41                 CFLAGS="${CFLAGS}"
  42                 INSTALL="${INSTALL-install}"
  43         )
  44         if use fontforge || use utils; then
  45                 emake "${buildargs[@]}"
  46         fi
  47 }
  48
  49 src_install() {
  50         local installargs=(
  51                 COMPRESS=0
  52                 DESTDIR="${ED}"
  53                 PCFDEST="${ED}${FONTDIR}"
  54                 TTFDEST="${ED}${FONTDIR}"
  55         )
  56         use utils || installargs+=( -C font )
  57         emake "${buildargs[@]}" "${installargs[@]}" install
  58         font_xfont_config
  59         font_fontconfig
  60 }