media-fonts/unifont/unifont-10.0.06.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit font toolchain-funcs xdg-utils
   7
   8 DESCRIPTION="GNU Unifont - a Pan-Unicode X11 bitmap iso10646 font"
   9 HOMEPAGE="http://unifoundry.com/"
  10 SRC_URI="mirror://gnu/${PN}/${P}/${P}.tar.gz"
  11
  12 LICENSE="GPL-2"
  13 SLOT="0"
  14 KEYWORDS="alpha amd64 arm ia64 ppc ppc64 ~s390 ~sh sparc x86 ~x86-fbsd"
  15 IUSE="fontforge utils"
  16
  17 DEPEND="
  18         fontforge? (
  19                 app-text/bdf2psf
  20                 dev-lang/perl
  21                 dev-perl/GD[png(-)]
  22                 media-gfx/fontforge
  23                 x11-apps/bdftopcf
  24         )
  25 "
  26 RDEPEND="
  27         utils? (
  28                 dev-lang/perl
  29                 dev-perl/GD[png(-)]
  30         )
  31 "
  32
  33 PATCHES=(
  34         "${FILESDIR}"/10.0.06-make.patch
  35 )
  36
  37 src_prepare() {
  38         sed -i -e 's/install -s/install/' src/Makefile || die
  39         default
  40 }
  41
  42 src_compile() {
  43         if use fontforge || use utils; then
  44                 tc-export CC
  45                 xdg_environment_reset
  46                 makeargs=(
  47                         CFLAGS="${CFLAGS}"
  48                         BUILDFONT=$(usex fontforge 1 '')
  49                 )
  50                 emake  "${makeargs[@]}"
  51         fi
  52 }
  53
  54 src_install() {
  55         makeargs+=(
  56                 DESTDIR="${ED%/}"
  57                 PCFDEST="${ED%/}${FONTDIR}"
  58                 TTFDEST="${ED%/}${FONTDIR}"
  59                 USRDIR=usr
  60         )
  61         use utils || makeargs+=( -C font )
  62         emake "${makeargs[@]}" install
  63         font_xfont_config
  64         font_fontconfig
  65 }