mate-base/mate-applets/mate-applets-1.22.2.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit mate
   7
   8 if [[ ${PV} != 9999 ]]; then
   9         KEYWORDS="~amd64 ~arm ~arm64 ~x86"
  10 fi
  11
  12 DESCRIPTION="Applets for the MATE Desktop and Panel"
  13 LICENSE="CC-BY-SA-3.0 FDL-1.1+ GPL-2+ GPL-3+ LGPL-2+"
  14 SLOT="0"
  15
  16 IUSE="X +cpupower ipv6 policykit +upower"
  17
  18 REQUIRED_USE="policykit? ( cpupower )"
  19
  20 COMMON_DEPEND="dev-libs/atk
  21         >=dev-libs/dbus-glib-0.74
  22         >=dev-libs/glib-2.50:2
  23         >=dev-libs/libmateweather-1.17.0
  24         >=dev-libs/libxml2-2.5:2
  25         >=gnome-base/libgtop-2.12.0:2=
  26         >=gnome-extra/gucharmap-3.0:2.90
  27         >=mate-base/mate-panel-1.17.0
  28         >=net-wireless/wireless-tools-28_pre9:0
  29         >=sys-apps/dbus-1.1.2
  30         x11-libs/gdk-pixbuf:2
  31         >=x11-libs/gtk+-3.22:3
  32         x11-libs/gtksourceview:3.0
  33         >=x11-libs/libnotify-0.7
  34         x11-libs/libX11
  35         >=x11-libs/libwnck-3.0:3
  36         x11-libs/pango
  37         virtual/libintl
  38         cpupower? (
  39                 sys-power/cpupower
  40                 policykit? ( >=sys-auth/polkit-0.97:0 )
  41         )
  42         upower? ( >=sys-power/upower-0.9.23 )
  43         !!net-analyzer/mate-netspeed"
  44
  45 RDEPEND="${COMMON_DEPEND}
  46         >=mate-base/mate-settings-daemon-1.6"
  47
  48 DEPEND="${COMMON_DEPEND}
  49         app-text/docbook-xml-dtd:4.3
  50         app-text/rarian
  51         >=app-text/scrollkeeper-dtd-1:1.0
  52         app-text/yelp-tools
  53         >=dev-util/intltool-0.50.1
  54         dev-libs/libxslt
  55         sys-devel/gettext:*
  56         virtual/pkgconfig:*"
  57
  58 src_configure() {
  59
  60         # configure.ac logic is a little hinky
  61         # and ignores --enable flags for cpufreq
  62         use cpupower || myconf="--disable-cpufreq"
  63
  64         mate_src_configure \
  65                 --libexecdir=/usr/libexec/mate-applets \
  66                 $(use_with X x) \
  67                 $(use_with upower) \
  68                 $(use_enable ipv6) \
  69                 $(use_enable policykit polkit) \
  70                 "${myconf[@]}"
  71 }
  72
  73 src_test() {
  74         unset DBUS_SESSION_BUS_ADDRESS
  75         emake check
  76 }
  77
  78 src_install() {
  79         mate_src_install
  80
  81         local APPLETS="accessx-status battstat charpick command cpufreq drivemount
  82                         geyes mateweather multiload netspeed stickynotes
  83                         timerapplet trashapplet"
  84
  85         for applet in ${APPLETS}; do
  86                 docinto ${applet}
  87
  88                 for d in AUTHORS ChangeLog NEWS README README.themes TODO; do
  89                         [ -s ${applet}/${d} ] && dodoc ${applet}/${d}
  90                 done
  91         done
  92 }