mate-base/caja/caja-1.24.0.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 MATE_LA_PUNT="yes"
   7
   8 inherit mate virtualx
   9
  10 if [[ ${PV} != 9999 ]]; then
  11         KEYWORDS="~amd64 ~arm ~arm64 ~x86"
  12 fi
  13
  14 DESCRIPTION="Caja file manager for the MATE desktop"
  15 LICENSE="GPL-2+ LGPL-2+"
  16 SLOT="0"
  17
  18 IUSE="+introspection +mate packagekit xmp"
  19
  20 COMMON_DEPEND="
  21         dev-libs/atk
  22         >=dev-libs/glib-2.58.1:2
  23         >=dev-libs/libxml2-2.4.7:2
  24         gnome-base/dconf
  25         >=gnome-base/gvfs-1.10.1:0[udisks]
  26         >=mate-base/mate-desktop-1.17.3:0
  27         >=media-libs/libexif-0.6.14:0
  28         x11-libs/cairo
  29         >=x11-libs/gdk-pixbuf-2.36.5:2
  30         >=x11-libs/gtk+-3.22:3[introspection?]
  31         >=x11-libs/libnotify-0.7.0:0
  32         x11-libs/libICE
  33         x11-libs/libSM
  34         x11-libs/libX11
  35         x11-libs/libXext
  36         x11-libs/libXft
  37         x11-libs/libXrender
  38         >=x11-libs/pango-1.1.2
  39         introspection? ( >=dev-libs/gobject-introspection-0.6.4:= )
  40         packagekit? ( app-admin/packagekit-base )
  41         xmp? ( >=media-libs/exempi-1.99.5:2 )
  42 "
  43
  44 RDEPEND="${COMMON_DEPEND}
  45         virtual/libintl
  46         !!mate-base/mate-file-manager
  47 "
  48
  49 DEPEND="${COMMON_DEPEND}
  50         >=dev-lang/perl-5:=
  51         dev-util/gdbus-codegen
  52         dev-util/glib-utils
  53         dev-util/gtk-doc
  54         dev-util/gtk-doc-am
  55         >=sys-devel/gettext-0.19.8:*
  56         virtual/pkgconfig"
  57
  58 PDEPEND="mate? ( >=x11-themes/mate-icon-theme-${MATE_BRANCH} )"
  59
  60 # TODO: Test fails because Caja is not merged yet:
  61 # GLib-GIO-ERROR **: Settings schema 'org.mate.caja.preferences' is not installed
  62 RESTRICT="test"
  63
  64 src_prepare() {
  65         # Remove unnecessary CFLAGS.
  66         sed -i -e 's:-DG.*DISABLE_DEPRECATED::g' \
  67                 configure.ac eel/Makefile.am || die
  68
  69         mate_src_prepare
  70 }
  71
  72 src_configure() {
  73         mate_src_configure \
  74                 --disable-update-mimedb \
  75                 $(use_enable introspection) \
  76                 $(use_enable packagekit) \
  77                 $(use_enable xmp)
  78 }
  79
  80 src_test() {
  81         unset SESSION_MANAGER
  82         unset DBUS_SESSION_BUS_ADDRESS
  83
  84         Xemake check || die "Test phase failed"
  85 }
  86
  87 pkg_postinst() {
  88         mate_pkg_postinst
  89
  90         elog "Caja can use gstreamer to preview audio files. Just make sure"
  91         elog "to have the necessary plugins available to play the media type you"
  92         elog "want to preview."
  93 }