mail-mta/msmtp/msmtp-1.6.2.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6 inherit multilib
   7
   8 DESCRIPTION="An SMTP client and SMTP plugin for mail user agents such as Mutt"
   9 HOMEPAGE="http://msmtp.sourceforge.net/"
  10 SRC_URI="mirror://sourceforge/msmtp/${P}.tar.xz"
  11
  12 LICENSE="GPL-3"
  13 SLOT="0"
  14 KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x86-macos"
  15 IUSE="doc gnutls idn libsecret +mta nls sasl ssl vim-syntax"
  16
  17 CDEPEND="
  18         idn? ( net-dns/libidn )
  19         libsecret? ( app-crypt/libsecret )
  20         nls? ( virtual/libintl )
  21         sasl? ( virtual/gsasl )
  22         ssl? (
  23                 gnutls? ( net-libs/gnutls )
  24                 !gnutls? ( dev-libs/openssl )
  25         )
  26 "
  27
  28 RDEPEND="${CDEPEND}
  29         net-mail/mailbase
  30         mta? (
  31                 !mail-mta/courier
  32                 !mail-mta/esmtp
  33                 !mail-mta/exim
  34                 !mail-mta/mini-qmail
  35                 !mail-mta/netqmail
  36                 !mail-mta/nullmailer
  37                 !mail-mta/postfix
  38                 !mail-mta/qmail-ldap
  39                 !mail-mta/sendmail
  40                 !mail-mta/opensmtpd
  41                 !<mail-mta/ssmtp-2.64-r2
  42                 !>=mail-mta/ssmtp-2.64-r2[mta]
  43         )
  44 "
  45
  46 DEPEND="${CDEPEND}
  47         doc? ( virtual/texi2dvi )
  48         nls? ( sys-devel/gettext )
  49         virtual/pkgconfig
  50 "
  51
  52 REQUIRED_USE="gnutls? ( ssl )"
  53
  54 DOCS="AUTHORS ChangeLog NEWS README THANKS doc/msmtprc*"
  55
  56 src_prepare() {
  57         # Use default Gentoo location for mail aliases
  58         sed -i 's:/etc/aliases:/etc/mail/aliases:' scripts/find_alias/find_alias_for_msmtp.sh || die
  59 }
  60
  61 src_configure() {
  62         econf \
  63                 $(use_enable nls) \
  64                 $(use_with ssl ssl $(usex gnutls gnutls openssl)) \
  65                 $(use_with sasl libgsasl) \
  66                 $(use_with idn libidn) \
  67                 $(use_with libsecret )
  68 }
  69
  70 src_compile() {
  71         default
  72
  73         if use doc ; then
  74                 cd doc || die
  75                 emake html pdf
  76         fi
  77 }
  78
  79 src_install() {
  80         default
  81
  82         if use doc ; then
  83                 dohtml doc/msmtp.html
  84                 dodoc doc/msmtp.pdf
  85         fi
  86
  87         if use mta ; then
  88                 dodir /usr/sbin
  89                 dosym /usr/bin/msmtp /usr/sbin/sendmail
  90                 dosym /usr/bin/msmtp /usr/bin/sendmail
  91                 dosym /usr/bin/msmtp /usr/$(get_libdir)/sendmail
  92         fi
  93
  94         if use vim-syntax ; then
  95                 insinto /usr/share/vim/vimfiles/syntax
  96                 doins scripts/vim/msmtp.vim
  97         fi
  98
  99         insinto /etc
 100         newins doc/msmtprc-system.example msmtprc
 101
 102         src_install_contrib find_alias find_alias_for_msmtp.sh
 103         src_install_contrib msmtpqueue "*.sh" "README ChangeLog"
 104         src_install_contrib msmtpq "msmtpq msmtp-queue" README.msmtpq
 105         src_install_contrib set_sendmail set_sendmail.sh set_sendmail.conf
 106 }
 107
 108 pkg_postinst() {
 109         if [[ -z ${REPLACING_VERSIONS} ]]; then
 110                 einfo "Please edit ${ROOT}etc/msmtprc before first use."
 111                 einfo "In addition, per user configuration files can be placed"
 112                 einfo "as '~/.msmtprc'.  See the msmtprc-user.example file under"
 113                 einfo "/usr/share/doc/${PF}/ for an example."
 114         fi
 115 }
 116
 117 src_install_contrib() {
 118         subdir="$1"
 119         bins="$2"
 120         docs="$3"
 121         local dir=/usr/share/${PN}/$subdir
 122         insinto ${dir}
 123         exeinto ${dir}
 124         for i in $bins ; do
 125                 doexe scripts/$subdir/$i
 126         done
 127         for i in $docs ; do
 128                 newdoc scripts/$subdir/$i $subdir.$i
 129         done
 130 }