mail-filter/milter-regex/milter-regex-2.7.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit toolchain-funcs
   7
   8 DESCRIPTION="A milter-based regular expression filter"
   9 HOMEPAGE="https://www.benzedrine.ch/milter-regex.html"
  10 SRC_URI="https://www.benzedrine.ch/${P}.tar.gz"
  11 LICENSE="BSD"
  12 SLOT="0"
  13 KEYWORDS="~amd64 ~x86"
  14 IUSE=""
  15
  16 RDEPEND="acct-user/milter-regex
  17         || ( mail-filter/libmilter mail-mta/sendmail )"
  18 DEPEND="${RDEPEND}
  19         virtual/yacc"
  20
  21 src_prepare() {
  22         eapply "${FILESDIR}/${PN}-2.6-gentoo.patch"
  23         eapply_user
  24         # Change default user
  25         sed -i -e 's/_\(milter-regex\)/\1/g' ${PN}.[8c]
  26 }
  27
  28 src_compile() {
  29         emake CC="$(tc-getCC)" -f Makefile.linux all
  30 }
  31
  32 src_install() {
  33         dobin ${PN}
  34         insinto /etc
  35         newins rules ${PN}.conf
  36         newconfd "${FILESDIR}/${PN}-conf-2.6" ${PN}
  37         newinitd "${FILESDIR}/${PN}-init" ${PN}
  38         doman *.8
  39 }
  40
  41 pkg_postinst() {
  42         elog "Postfix configuration example (add to main.cf or master.cf):"
  43         elog "  smtpd_milters=unix:/run/milter-regex/socket"
  44         elog "Sendmail configuration example:"
  45         elog "  INPUT_MAIL_FILTER(\`${PN}',\`S=unix:/run/milter-regex/socket,T=S:30s;R:2m')"
  46 }