mail-client/sylpheed/sylpheed-3.7.0.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="6"
   5
   6 inherit eutils
   7
   8 DESCRIPTION="A lightweight email client and newsreader"
   9 HOMEPAGE="http://sylpheed.sraoss.jp/"
  10 SRC_URI="http://${PN}.sraoss.jp/${PN}/v${PV%.*}/${P}.tar.bz2"
  11
  12 LICENSE="GPL-2 LGPL-2.1"
  13 SLOT="0"
  14 KEYWORDS="alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 sparc x86 ~x86-fbsd"
  15 IUSE="crypt ipv6 ldap libressl nls oniguruma pda spell ssl xface"
  16
  17 CDEPEND="net-libs/liblockfile
  18         x11-libs/gtk+:2
  19         crypt? ( app-crypt/gpgme )
  20         ldap? ( net-nds/openldap )
  21         nls? ( sys-devel/gettext )
  22         oniguruma? ( dev-libs/oniguruma:= )
  23         pda? ( app-pda/jpilot )
  24         spell? (
  25                 app-text/gtkspell:2
  26                 dev-libs/dbus-glib
  27         )
  28         ssl? (
  29                 !libressl? ( dev-libs/openssl:0 )
  30                 libressl? ( dev-libs/libressl )
  31         )"
  32 RDEPEND="${CDEPEND}
  33         app-misc/mime-types
  34         net-misc/curl"
  35 DEPEND="${CDEPEND}
  36         virtual/pkgconfig
  37         xface? ( media-libs/compface )"
  38
  39 DOCS="AUTHORS ChangeLog* NEW* PLUGIN* README* TODO*"
  40
  41 src_configure() {
  42         local htmldir="${EPREFIX}"/usr/share/doc/${PF}/html
  43         econf \
  44                 $(use_enable crypt gpgme) \
  45                 $(use_enable ipv6) \
  46                 $(use_enable ldap) \
  47                 $(use_enable oniguruma) \
  48                 $(use_enable pda jpilot) \
  49                 $(use_enable spell gtkspell) \
  50                 $(use_enable ssl) \
  51                 $(use_enable xface compface) \
  52                 --with-plugindir="${EPREFIX}"/usr/$(get_libdir)/${PN}/plugins \
  53                 --with-manualdir="${htmldir}"/manual \
  54                 --with-faqdir="${htmldir}"/faq \
  55                 --disable-updatecheck
  56 }
  57
  58 src_install() {
  59         default
  60
  61         doicon *.png
  62         domenu *.desktop
  63
  64         cd plugin/attachment_tool
  65         emake DESTDIR="${D}" install-plugin
  66         docinto plugin/attachment_tool
  67         dodoc README
  68 }