mail-client/evolution/evolution-3.22.4.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=6
   6 GNOME2_LA_PUNT="yes"
   7
   8 inherit gnome2 flag-o-matic readme.gentoo-r1
   9
  10 DESCRIPTION="Integrated mail, addressbook and calendaring functionality"
  11 HOMEPAGE="https://wiki.gnome.org/Apps/Evolution"
  12
  13 # Note: explicitly "|| ( LGPL-2 LGPL-3 )", not "LGPL-2+".
  14 LICENSE="|| ( LGPL-2 LGPL-3 ) CC-BY-SA-3.0 FDL-1.3+ OPENLDAP"
  15 SLOT="2.0"
  16
  17 IUSE="+bogofilter crypt geolocation highlight ldap spamassassin spell ssl +weather"
  18
  19 KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~x86 ~x86-fbsd"
  20
  21 # We need a graphical pinentry frontend to be able to ask for the GPG
  22 # password from inside evolution, bug 160302
  23 PINENTRY_DEPEND="|| ( app-crypt/pinentry[gnome-keyring] app-crypt/pinentry[gtk] app-crypt/pinentry[qt4] app-crypt/pinentry[qt5] )"
  24
  25 # glade-3 support is for maintainers only per configure.ac
  26 # pst is not mature enough and changes API/ABI frequently
  27 # dconf explicitely needed for backup plugin
  28 # gnome-desktop support is optional with --enable-gnome-desktop
  29 # gnome-autoar (currently disabled because no release has been made)
  30 COMMON_DEPEND="
  31         >=app-crypt/gcr-3.4:=
  32         >=app-text/enchant-1.1.7
  33         >=dev-libs/glib-2.46:2[dbus]
  34         >=dev-libs/libxml2-2.7.3:2
  35         >=gnome-base/gnome-desktop-2.91.3:3=
  36         >=gnome-base/gsettings-desktop-schemas-2.91.92
  37         >=gnome-extra/evolution-data-server-${PV}:=[gtk,weather?]
  38         >=media-libs/libcanberra-0.25[gtk3]
  39         >=net-libs/libsoup-2.42:2.4
  40         >=net-libs/webkit-gtk-2.13.90:4
  41         >=x11-libs/cairo-1.9.15:=[glib]
  42         >=x11-libs/gdk-pixbuf-2.24:2
  43         >=x11-libs/gtk+-3.10:3
  44         >=x11-libs/libnotify-0.7:=
  45         >=x11-misc/shared-mime-info-0.22
  46
  47         >=app-text/iso-codes-0.49
  48         dev-libs/atk
  49         gnome-base/dconf
  50         dev-libs/libical:=
  51         x11-libs/libSM
  52         x11-libs/libICE
  53
  54         crypt? (
  55                 >=app-crypt/gnupg-1.4
  56                 ${PINENTRY_DEPEND}
  57                 x11-libs/libcryptui )
  58         geolocation? (
  59                 >=media-libs/libchamplain-0.12:0.12[gtk]
  60                 >=media-libs/clutter-1.0.0:1.0
  61                 >=media-libs/clutter-gtk-0.90:1.0
  62                 >=sci-geosciences/geocode-glib-3.10.0
  63                 x11-libs/mx:1.0 )
  64         ldap? ( >=net-nds/openldap-2:= )
  65         spell? ( app-text/gtkspell:3 )
  66         ssl? (
  67                 >=dev-libs/nspr-4.6.1:=
  68                 >=dev-libs/nss-3.11:= )
  69         weather? ( >=dev-libs/libgweather-3.10:2= )
  70 "
  71 DEPEND="${COMMON_DEPEND}
  72         app-text/docbook-xml-dtd:4.1.2
  73         app-text/yelp-tools
  74         >=dev-util/gtk-doc-am-1.14
  75         >=dev-util/intltool-0.40.0
  76         >=gnome-base/gnome-common-2.12
  77         virtual/pkgconfig
  78 "
  79 RDEPEND="${COMMON_DEPEND}
  80         bogofilter? ( mail-filter/bogofilter )
  81         highlight? ( app-text/highlight )
  82         spamassassin? ( mail-filter/spamassassin )
  83         !gnome-extra/evolution-exchange
  84 "
  85
  86 DISABLE_AUTOFORMATTING="yes"
  87 DOC_CONTENTS="To change the default browser if you are not using GNOME, edit
  88 ~/.local/share/applications/mimeapps.list so it includes the
  89 following content:
  90
  91 [Default Applications]
  92 x-scheme-handler/http=firefox.desktop
  93 x-scheme-handler/https=firefox.desktop
  94
  95 (replace firefox.desktop with the name of the appropriate .desktop
  96 file from /usr/share/applications if you use a different browser)."
  97
  98 src_configure() {
  99         # Use NSS/NSPR only if 'ssl' is enabled.
 100         gnome2_src_configure \
 101                 --without-glade-catalog \
 102                 --disable-autoar \
 103                 --disable-code-coverage \
 104                 --disable-installed-tests \
 105                 --disable-pst-import \
 106                 --enable-canberra \
 107                 $(use_enable crypt libcryptui) \
 108                 $(use_enable highlight text-highlight) \
 109                 $(use_enable geolocation contact-maps) \
 110                 $(use_enable spell gtkspell) \
 111                 $(use_enable ssl nss) \
 112                 $(use_enable ssl smime) \
 113                 $(use_with bogofilter) \
 114                 $(use_with ldap openldap) \
 115                 $(use_with spamassassin) \
 116                 $(usex ssl --enable-nss=yes "--without-nspr-libs
 117                         --without-nspr-includes
 118                         --without-nss-libs
 119                         --without-nss-includes") \
 120                 $(use_enable weather)
 121 }
 122
 123 src_install() {
 124         gnome2_src_install
 125
 126         # Problems with prelink:
 127         # https://bugzilla.gnome.org/show_bug.cgi?id=731680
 128         # https://bugzilla.gnome.org/show_bug.cgi?id=732148
 129         # https://bugzilla.redhat.com/show_bug.cgi?id=1114538
 130         echo PRELINK_PATH_MASK=/usr/bin/evolution > ${T}/99${PN}
 131         doenvd "${T}"/99${PN}
 132
 133         readme.gentoo_create_doc
 134 }
 135
 136 pkg_postinst() {
 137         gnome2_pkg_postinst
 138         readme.gentoo_print_elog
 139 }