lxde-base/lxdm/lxdm-0.5.3-r1.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 # Using strip-linguas in eutils
   7 inherit eutils autotools systemd
   8
   9 DESCRIPTION="LXDE Display Manager"
  10 HOMEPAGE="https://wiki.lxde.org/en/LXDM"
  11 SRC_URI="mirror://sourceforge/lxde/${P}.tar.xz"
  12
  13 LICENSE="GPL-3"
  14 SLOT="0"
  15 KEYWORDS="amd64 ~arm ~ppc x86"
  16
  17 IUSE="consolekit debug gtk3 nls pam"
  18
  19 RDEPEND="consolekit? ( sys-auth/consolekit )
  20         x11-libs/libxcb
  21         gtk3? ( x11-libs/gtk+:3 )
  22         !gtk3? ( x11-libs/gtk+:2 )
  23         nls? ( sys-devel/gettext )
  24         pam? ( virtual/pam )"
  25 DEPEND="${RDEPEND}
  26         >=dev-util/intltool-0.40
  27         virtual/pkgconfig"
  28 DOCS=( AUTHORS README TODO )
  29
  30 src_prepare() {
  31         # Upstream bug, tarball contains pre-made lxdm.conf
  32         rm "${S}"/data/lxdm.conf || die
  33
  34         # Fix consolekit and selinux
  35         eapply "${FILESDIR}/${P}-pam_console-disable.patch"
  36         # Apply all upstream fixes in git until 2016-11-11
  37         eapply "${FILESDIR}/lxdm-0.5.3-upstream-fixes.patch"
  38         eapply_user
  39
  40         # this replaces the bootstrap/autogen script in most packages
  41         eautoreconf
  42
  43         # process LINGUAS
  44         if use nls; then
  45                 einfo "Running intltoolize ..."
  46                 intltoolize --force --copy --automake || die
  47                 strip-linguas -i "${S}/po" || die
  48         fi
  49 }
  50 src_configure() {
  51         econf   --enable-password \
  52                 --with-x \
  53                 --with-xconn=xcb \
  54                 --with-systemdsystemunitdir=$(systemd_get_systemunitdir) \
  55                 $(use_enable consolekit) \
  56                 $(use_enable gtk3) \
  57                 $(use_enable nls) \
  58                 $(use_enable debug) \
  59                 $(use_with pam)
  60 }
  61
  62 src_install() {
  63         default_src_install
  64
  65         #Use Gentoo specific Xsession startup file
  66         exeinto /etc/${PN}
  67         doexe "${FILESDIR}"/Xsession
  68 }