kde-plasma/powerdevil/powerdevil-5.14.2.ebuild

   1 # Copyright 1999-2018 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 KDE_HANDBOOK="true"
   7 inherit kde5
   8
   9 DESCRIPTION="Power management for KDE Plasma Shell"
  10 HOMEPAGE="https://cgit.kde.org/powerdevil.git"
  11 KEYWORDS="~amd64 ~arm ~x86"
  12 IUSE="brightness-control consolekit +wireless"
  13
  14 DEPEND="
  15         $(add_frameworks_dep kactivities)
  16         $(add_frameworks_dep kauth policykit)
  17         $(add_frameworks_dep kcompletion)
  18         $(add_frameworks_dep kconfig)
  19         $(add_frameworks_dep kconfigwidgets)
  20         $(add_frameworks_dep kcoreaddons)
  21         $(add_frameworks_dep kcrash)
  22         $(add_frameworks_dep kdbusaddons)
  23         $(add_frameworks_dep kglobalaccel)
  24         $(add_frameworks_dep ki18n)
  25         $(add_frameworks_dep kidletime)
  26         $(add_frameworks_dep kio)
  27         $(add_frameworks_dep knotifications)
  28         $(add_frameworks_dep knotifyconfig)
  29         $(add_frameworks_dep kservice)
  30         $(add_frameworks_dep kwayland)
  31         $(add_frameworks_dep kwidgetsaddons)
  32         $(add_frameworks_dep kxmlgui)
  33         $(add_frameworks_dep solid)
  34         $(add_plasma_dep libkscreen)
  35         $(add_plasma_dep libkworkspace)
  36         $(add_qt_dep qtdbus)
  37         $(add_qt_dep qtgui)
  38         $(add_qt_dep qtwidgets)
  39         $(add_qt_dep qtx11extras)
  40         virtual/libudev:=
  41         x11-libs/libxcb
  42         brightness-control? ( app-misc/ddcutil )
  43         wireless? (
  44                 $(add_frameworks_dep bluez-qt)
  45                 $(add_frameworks_dep networkmanager-qt)
  46         )
  47 "
  48 RDEPEND="${DEPEND}
  49         $(add_plasma_dep kde-cli-tools)
  50         >=sys-power/upower-0.9.23
  51         consolekit? (
  52                 >=sys-auth/consolekit-1.0.1
  53                 sys-power/pm-utils
  54         )
  55         !kde-plasma/powerdevil:4
  56         !kde-plasma/systemsettings:4[handbook]
  57 "
  58
  59 src_configure() {
  60         local mycmakeargs=(
  61                 -DWITH_DDCUTIL=$(usex brightness-control)
  62                 $(cmake-utils_use_find_package wireless KF5BluezQt)
  63                 $(cmake-utils_use_find_package wireless KF5NetworkManagerQt)
  64         )
  65
  66         kde5_src_configure
  67 }