kde-plasma/plasma-workspace/plasma-workspace-5.5.2-r1.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6
   7 KDE_HANDBOOK="true"
   8 KDE_PUNT_BOGUS_DEPS="true"
   9 KDE_TEST="true"
  10 QT_MINIMAL="5.5.0"
  11 VIRTUALX_REQUIRED="test"
  12 inherit kde5 multilib qmake-utils
  13
  14 DESCRIPTION="KDE Plasma workspace"
  15 KEYWORDS="~amd64 ~x86"
  16 IUSE="dbus +geolocation gps prison qalculate"
  17
  18 COMMON_DEPEND="
  19         $(add_frameworks_dep baloo)
  20         $(add_frameworks_dep kactivities)
  21         $(add_frameworks_dep kauth)
  22         $(add_frameworks_dep kbookmarks)
  23         $(add_frameworks_dep kcmutils)
  24         $(add_frameworks_dep kcompletion)
  25         $(add_frameworks_dep kconfig)
  26         $(add_frameworks_dep kconfigwidgets)
  27         $(add_frameworks_dep kcoreaddons)
  28         $(add_frameworks_dep kcrash)
  29         $(add_frameworks_dep kdbusaddons)
  30         $(add_frameworks_dep kdeclarative)
  31         $(add_frameworks_dep kdelibs4support)
  32         $(add_frameworks_dep kdesu)
  33         $(add_frameworks_dep kglobalaccel)
  34         $(add_frameworks_dep kguiaddons)
  35         $(add_frameworks_dep ki18n)
  36         $(add_frameworks_dep kiconthemes)
  37         $(add_frameworks_dep kidletime)
  38         $(add_frameworks_dep kio)
  39         $(add_frameworks_dep kitemviews)
  40         $(add_frameworks_dep kjobwidgets)
  41         $(add_frameworks_dep kjs)
  42         $(add_frameworks_dep kjsembed)
  43         $(add_frameworks_dep knewstuff)
  44         $(add_frameworks_dep knotifications)
  45         $(add_frameworks_dep knotifyconfig)
  46         $(add_frameworks_dep kpackage)
  47         $(add_frameworks_dep krunner)
  48         $(add_frameworks_dep kservice)
  49         $(add_frameworks_dep ktexteditor)
  50         $(add_frameworks_dep ktextwidgets)
  51         $(add_frameworks_dep kwallet)
  52         $(add_frameworks_dep kwidgetsaddons)
  53         $(add_frameworks_dep kwindowsystem)
  54         $(add_frameworks_dep kxmlgui)
  55         $(add_frameworks_dep kxmlrpcclient)
  56         $(add_frameworks_dep plasma)
  57         $(add_frameworks_dep solid)
  58         $(add_plasma_dep kscreenlocker)
  59         $(add_plasma_dep kwayland)
  60         $(add_plasma_dep kwin)
  61         $(add_plasma_dep libkscreen)
  62         $(add_plasma_dep libksysguard)
  63         dev-qt/qtconcurrent:5
  64         dev-qt/qtdbus:5
  65         dev-qt/qtdeclarative:5[widgets]
  66         dev-qt/qtgui:5[jpeg]
  67         dev-qt/qtnetwork:5
  68         dev-qt/qtscript:5
  69         dev-qt/qtsql:5
  70         dev-qt/qtwidgets:5
  71         dev-qt/qtx11extras:5
  72         dev-qt/qtxml:5
  73         media-libs/phonon[qt5]
  74         sys-libs/zlib
  75         x11-libs/libICE
  76         x11-libs/libSM
  77         x11-libs/libX11
  78         x11-libs/libXau
  79         x11-libs/libxcb
  80         x11-libs/libXfixes
  81         x11-libs/libXrender
  82         x11-libs/xcb-util
  83         x11-libs/xcb-util-image
  84         dbus? ( dev-libs/libdbusmenu-qt[qt5] )
  85         geolocation? ( $(add_frameworks_dep networkmanager-qt) )
  86         gps? ( sci-geosciences/gpsd )
  87         prison? ( media-libs/prison:5 )
  88         qalculate? ( sci-libs/libqalculate )
  89 "
  90 RDEPEND="${COMMON_DEPEND}
  91         $(add_frameworks_dep kded)
  92         $(add_kdeapps_dep kio-extras)
  93         $(add_plasma_dep kde-cli-tools)
  94         $(add_plasma_dep ksysguard)
  95         $(add_plasma_dep milou)
  96         dev-qt/qdbus:5
  97         dev-qt/qtpaths:5
  98         dev-qt/qtquickcontrols:5[widgets]
  99         x11-apps/mkfontdir
 100         x11-apps/xmessage
 101         x11-apps/xprop
 102         x11-apps/xrdb
 103         x11-apps/xset
 104         x11-apps/xsetroot
 105         !dev-libs/xembed-sni-proxy
 106         !kde-base/freespacenotifier:4
 107         !kde-base/libtaskmanager:4
 108         !kde-base/kcminit:4
 109         !kde-base/kdebase-startkde:4
 110         !kde-base/klipper:4
 111         !kde-base/krunner:4
 112         !kde-base/ksmserver:4
 113         !kde-base/ksplash:4
 114         !kde-base/plasma-workspace:4
 115 "
 116 DEPEND="${COMMON_DEPEND}
 117         x11-proto/xproto
 118 "
 119
 120 PATCHES=( "${FILESDIR}/${PN}-5.4-startkde-script.patch" )
 121
 122 RESTRICT="test"
 123
 124 src_prepare() {
 125         # whole patch should be upstreamed, doesn't work in PATCHES
 126         epatch "${FILESDIR}/${PN}-tests-optional.patch"
 127
 128         kde5_src_prepare
 129
 130         sed -e "s|\`qtpaths|\`$(qt5_get_bindir)/qtpaths|" \
 131                 -i startkde/startkde.cmake startkde/startplasmacompositor.cmake || die
 132
 133         if ! use geolocation; then
 134                 punt_bogus_dep KF5 NetworkManagerQt
 135                 pushd dataengines > /dev/null || die
 136                         comment_add_subdirectory geolocation
 137                 popd > /dev/null || die
 138         fi
 139 }
 140
 141 src_configure() {
 142         local mycmakeargs=(
 143                 $(cmake-utils_use_find_package dbus dbusmenu-qt5)
 144                 $(cmake-utils_use_find_package gps libgps)
 145                 $(cmake-utils_use_find_package prison)
 146                 $(cmake-utils_use_find_package qalculate Qalculate)
 147         )
 148
 149         kde5_src_configure
 150 }
 151
 152 src_install() {
 153         kde5_src_install
 154
 155         # startup and shutdown scripts
 156         insinto /etc/plasma/startup
 157         doins "${FILESDIR}/10-agent-startup.sh"
 158
 159         insinto /etc/plasma/shutdown
 160         doins "${FILESDIR}/10-agent-shutdown.sh"
 161 }
 162
 163 pkg_postinst () {
 164         kde5_pkg_postinst
 165
 166         echo
 167         elog "To enable gpg-agent and/or ssh-agent in Plasma sessions,"
 168         elog "edit ${EPREFIX}/etc/plasma/startup/10-agent-startup.sh and"
 169         elog "${EPREFIX}/etc/plasma/shutdown/10-agent-shutdown.sh"
 170         echo
 171 }