kde-plasma/plasma-nm/plasma-nm-5.18.5-r1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 ECM_TEST="true"
   7 KFMIN=5.66.0
   8 PVCUT=$(ver_cut 1-3)
   9 QTMIN=5.12.3
  10 inherit ecm kde.org
  11
  12 DESCRIPTION="KDE Plasma applet for NetworkManager"
  13
  14 LICENSE="GPL-2 LGPL-2.1"
  15 SLOT="5"
  16 KEYWORDS="amd64 ~arm arm64 ~ppc64 x86"
  17 IUSE="modemmanager openconnect teamd"
  18
  19 DEPEND="
  20         >=app-crypt/qca-2.1.1:2[qt5(+)]
  21         >=dev-qt/qtdbus-${QTMIN}:5
  22         >=dev-qt/qtdeclarative-${QTMIN}:5[widgets]
  23         >=dev-qt/qtgui-${QTMIN}:5
  24         >=dev-qt/qtnetwork-${QTMIN}:5
  25         >=dev-qt/qtwidgets-${QTMIN}:5
  26         >=kde-frameworks/kcompletion-${KFMIN}:5
  27         >=kde-frameworks/kconfig-${KFMIN}:5
  28         >=kde-frameworks/kconfigwidgets-${KFMIN}:5
  29         >=kde-frameworks/kcoreaddons-${KFMIN}:5
  30         >=kde-frameworks/kdbusaddons-${KFMIN}:5
  31         >=kde-frameworks/kdeclarative-${KFMIN}:5
  32         >=kde-frameworks/ki18n-${KFMIN}:5
  33         >=kde-frameworks/kiconthemes-${KFMIN}:5
  34         >=kde-frameworks/kio-${KFMIN}:5
  35         >=kde-frameworks/kitemviews-${KFMIN}:5
  36         >=kde-frameworks/knotifications-${KFMIN}:5
  37         >=kde-frameworks/kservice-${KFMIN}:5
  38         >=kde-frameworks/kwallet-${KFMIN}:5
  39         >=kde-frameworks/kwidgetsaddons-${KFMIN}:5
  40         >=kde-frameworks/kwindowsystem-${KFMIN}:5
  41         >=kde-frameworks/kxmlgui-${KFMIN}:5
  42         >=kde-frameworks/networkmanager-qt-${KFMIN}:5[teamd=]
  43         >=kde-frameworks/plasma-${KFMIN}:5
  44         >=kde-frameworks/solid-${KFMIN}:5
  45         net-misc/networkmanager[teamd=]
  46         modemmanager? (
  47                 >=kde-frameworks/modemmanager-qt-${KFMIN}:5
  48                 >=dev-qt/qtxml-${QTMIN}:5
  49                 net-misc/mobile-broadband-provider-info
  50         )
  51         openconnect? (
  52                 >=dev-qt/qtxml-${QTMIN}:5
  53                 net-vpn/networkmanager-openconnect
  54                 net-vpn/openconnect:=
  55         )
  56 "
  57 RDEPEND="${DEPEND}
  58         >=dev-qt/qtquickcontrols-${QTMIN}:5
  59         >=dev-qt/qtquickcontrols2-${QTMIN}:5
  60         >=kde-plasma/kde-cli-tools-${PVCUT}:5
  61 "
  62
  63 PATCHES=( "${FILESDIR}/${P}-missing-wireguard-icon.patch" ) # in Plasma/5.18
  64
  65 src_configure() {
  66         local mycmakeargs=(
  67                 -DDISABLE_MODEMMANAGER_SUPPORT=$(usex !modemmanager)
  68                 $(cmake_use_find_package modemmanager KF5ModemManagerQt)
  69                 $(cmake_use_find_package openconnect OpenConnect)
  70         )
  71
  72         ecm_src_configure
  73 }
  74
  75 pkg_postinst() {
  76         ecm_pkg_postinst
  77
  78         if ! has_version "kde-plasma/plasma-workspace:5"; then
  79                 elog "${PN} is not terribly useful without kde-plasma/plasma-workspace:5."
  80                 elog "However, the networkmanagement KCM can be called from either systemsettings"
  81                 elog "or manually: $ kcmshell5 kcm_networkmanagement"
  82         fi
  83 }