kde-plasma/plasma-desktop/plasma-desktop-5.15.3.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 KDE_HANDBOOK="forceoptional"
   7 KDE_TEST="true"
   8 VIRTUALX_REQUIRED="test"
   9 inherit kde5
  10
  11 DESCRIPTION="KDE Plasma desktop"
  12 KEYWORDS="~amd64 ~arm ~arm64 ~x86"
  13 IUSE="appstream +fontconfig ibus +mouse scim +semantic-desktop touchpad"
  14
  15 COMMON_DEPEND="
  16         $(add_frameworks_dep attica)
  17         $(add_frameworks_dep kactivities)
  18         $(add_frameworks_dep kactivities-stats)
  19         $(add_frameworks_dep karchive)
  20         $(add_frameworks_dep kauth)
  21         $(add_frameworks_dep kbookmarks)
  22         $(add_frameworks_dep kcmutils)
  23         $(add_frameworks_dep kcodecs)
  24         $(add_frameworks_dep kcompletion)
  25         $(add_frameworks_dep kconfig)
  26         $(add_frameworks_dep kconfigwidgets)
  27         $(add_frameworks_dep kcoreaddons)
  28         $(add_frameworks_dep kdbusaddons)
  29         $(add_frameworks_dep kdeclarative)
  30         $(add_frameworks_dep kded)
  31         $(add_frameworks_dep kdelibs4support)
  32         $(add_frameworks_dep kemoticons)
  33         $(add_frameworks_dep kglobalaccel)
  34         $(add_frameworks_dep kguiaddons)
  35         $(add_frameworks_dep ki18n)
  36         $(add_frameworks_dep kiconthemes)
  37         $(add_frameworks_dep kio)
  38         $(add_frameworks_dep kitemmodels)
  39         $(add_frameworks_dep kitemviews)
  40         $(add_frameworks_dep kjobwidgets)
  41         $(add_frameworks_dep knewstuff)
  42         $(add_frameworks_dep knotifications)
  43         $(add_frameworks_dep knotifyconfig)
  44         $(add_frameworks_dep kparts)
  45         $(add_frameworks_dep kpeople)
  46         $(add_frameworks_dep krunner)
  47         $(add_frameworks_dep kservice)
  48         $(add_frameworks_dep kwallet)
  49         $(add_frameworks_dep kwidgetsaddons)
  50         $(add_frameworks_dep kwindowsystem)
  51         $(add_frameworks_dep kxmlgui)
  52         $(add_frameworks_dep plasma)
  53         $(add_frameworks_dep solid)
  54         $(add_frameworks_dep sonnet)
  55         $(add_plasma_dep kwin)
  56         $(add_plasma_dep plasma-workspace)
  57         $(add_qt_dep qtconcurrent)
  58         $(add_qt_dep qtdbus)
  59         $(add_qt_dep qtdeclarative)
  60         $(add_qt_dep qtgui)
  61         $(add_qt_dep qtnetwork)
  62         $(add_qt_dep qtprintsupport)
  63         $(add_qt_dep qtsql)
  64         $(add_qt_dep qtsvg)
  65         $(add_qt_dep qtwidgets)
  66         $(add_qt_dep qtx11extras)
  67         $(add_qt_dep qtxml)
  68         media-libs/phonon[qt5(+)]
  69         x11-libs/libX11
  70         x11-libs/libXcursor
  71         x11-libs/libXfixes
  72         x11-libs/libXi
  73         x11-libs/libxcb
  74         x11-libs/libxkbfile
  75         appstream? ( >=dev-libs/appstream-0.12.2[qt5] )
  76         fontconfig? (
  77                 media-libs/fontconfig
  78                 media-libs/freetype
  79                 x11-libs/libXft
  80                 x11-libs/xcb-util-image
  81         )
  82         ibus? (
  83                 $(add_qt_dep qtx11extras)
  84                 app-i18n/ibus
  85                 dev-libs/glib:2
  86                 x11-libs/libxcb
  87                 x11-libs/xcb-util-keysyms
  88         )
  89         scim? ( app-i18n/scim )
  90         semantic-desktop? ( $(add_frameworks_dep baloo) )
  91         touchpad? ( x11-drivers/xf86-input-synaptics )
  92 "
  93 DEPEND="${COMMON_DEPEND}
  94         dev-libs/boost
  95         x11-base/xorg-proto
  96         fontconfig? ( x11-libs/libXrender )
  97         mouse? (
  98                 x11-drivers/xf86-input-evdev
  99                 x11-drivers/xf86-input-libinput
 100         )
 101 "
 102 RDEPEND="${COMMON_DEPEND}
 103         $(add_frameworks_dep kirigami)
 104         $(add_frameworks_dep qqc2-desktop-style)
 105         $(add_plasma_dep breeze)
 106         $(add_plasma_dep kde-cli-tools)
 107         $(add_plasma_dep oxygen)
 108         $(add_qt_dep qtgraphicaleffects)
 109         $(add_qt_dep qtquickcontrols2)
 110         sys-apps/util-linux
 111         x11-apps/setxkbmap
 112         !kde-apps/kcontrol
 113         !<kde-apps/kde4-l10n-17.08.1-r1
 114         !kde-apps/knetattach[handbook]
 115 "
 116
 117 src_prepare() {
 118         rm -r po/id/docs || die "failed to remove Indonesian docs" # bug 680162
 119         kde5_src_prepare
 120 }
 121
 122 src_configure() {
 123         local mycmakeargs=(
 124                 $(cmake-utils_use_find_package appstream AppStreamQt)
 125                 $(cmake-utils_use_find_package fontconfig Fontconfig)
 126                 $(cmake-utils_use_find_package ibus IBus)
 127                 $(cmake-utils_use_find_package mouse Evdev)
 128                 $(cmake-utils_use_find_package mouse XorgLibinput)
 129                 $(cmake-utils_use_find_package scim SCIM)
 130                 $(cmake-utils_use_find_package semantic-desktop KF5Baloo)
 131                 $(cmake-utils_use_find_package touchpad Synaptics)
 132         )
 133
 134         kde5_src_configure
 135 }
 136
 137 src_test() {
 138         # parallel tests fail, foldermodeltest,positionertest hang, bug #646890
 139         # needs D-Bus, bug #634166
 140         local myctestargs=(
 141                 -j1
 142                 -E "(foldermodeltest|positionertest|test_kio_fonts)"
 143         )
 144
 145         kde5_src_test
 146 }