kde-plasma/libkworkspace/libkworkspace-5.17.4.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 ECM_TEST="true"
   7 KDE_ORG_NAME="plasma-workspace"
   8 KFMIN=5.64.0
   9 PVCUT=$(ver_cut 1-3)
  10 QTMIN=5.12.3
  11 inherit ecm kde.org
  12
  13 DESCRIPTION="Workspace library to interact with the Plasma session manager"
  14
  15 LICENSE="GPL-2" # TODO: CHECK
  16 SLOT="5"
  17 KEYWORDS="amd64 ~arm arm64 x86"
  18 IUSE=""
  19
  20 COMMON_DEPEND="
  21         >=kde-frameworks/kcoreaddons-${KFMIN}:5
  22         >=kde-frameworks/ki18n-${KFMIN}:5
  23         >=kde-frameworks/kwindowsystem-${KFMIN}:5
  24         >=kde-frameworks/plasma-${KFMIN}:5
  25         >=kde-plasma/kscreenlocker-${PVCUT}:5
  26         >=dev-qt/qtdbus-${QTMIN}:5
  27         >=dev-qt/qtx11extras-${QTMIN}:5
  28         x11-libs/libICE
  29         x11-libs/libSM
  30         x11-libs/libX11
  31         x11-libs/libXau
  32 "
  33 DEPEND="${COMMON_DEPEND}
  34         >=kde-plasma/kwin-${PVCUT}:5
  35 "
  36 RDEPEND="${COMMON_DEPEND}
  37         !<kde-plasma/plasma-workspace-5.14.2:5
  38 "
  39
  40 S="${S}/${PN}"
  41
  42 PATCHES=( "${FILESDIR}/${PN}-5.16.80-standalone.patch" )
  43
  44 src_prepare() {
  45         # delete colliding libkworkspace translations, let ecm_src_prepare do its magic
  46         if [[ ${KDE_BUILD_TYPE} = release ]]; then
  47                 find ../po -type f -name "*po" -and -not -name "libkworkspace*" -delete || die
  48                 rm -rf po/*/docs || die
  49                 cp -a ../po ./ || die
  50         fi
  51         ecm_src_prepare
  52         if [[ ${KDE_BUILD_TYPE} = release ]]; then
  53                 cat >> CMakeLists.txt <<- _EOF_ || die
  54                         ki18n_install(po)
  55                 _EOF_
  56         fi
  57
  58         sed -e "/set/s/GENTOO_PV/$(ver_cut 1-3)/" \
  59                 -i CMakeLists.txt || die "Failed to prepare CMakeLists.txt"
  60 }