kde-plasma/libksysguard/libksysguard-5.17.4.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 ECM_TEST="true"
   7 VIRTUALX_REQUIRED="test"
   8 KFMIN=5.64.0
   9 PVCUT=$(ver_cut 1-3)
  10 QTMIN=5.12.3
  11 inherit ecm kde.org
  12
  13 DESCRIPTION="Task management and system monitoring library"
  14 LICENSE="LGPL-2+"
  15 SLOT="5"
  16 KEYWORDS="~amd64 ~arm ~arm64 ~x86"
  17 IUSE="minimal webengine X"
  18
  19 RDEPEND="
  20         >=dev-qt/qtdbus-${QTMIN}:5
  21         >=dev-qt/qtgui-${QTMIN}:5
  22         >=dev-qt/qtnetwork-${QTMIN}:5
  23         >=dev-qt/qtwebchannel-${QTMIN}:5
  24         >=dev-qt/qtwidgets-${QTMIN}:5
  25         >=kde-frameworks/kauth-${KFMIN}:5
  26         >=kde-frameworks/kcompletion-${KFMIN}:5
  27         >=kde-frameworks/kconfig-${KFMIN}:5
  28         >=kde-frameworks/kconfigwidgets-${KFMIN}:5
  29         >=kde-frameworks/kcoreaddons-${KFMIN}:5
  30         >=kde-frameworks/ki18n-${KFMIN}:5
  31         >=kde-frameworks/kwidgetsaddons-${KFMIN}:5
  32         >=kde-frameworks/kwindowsystem-${KFMIN}:5
  33         sys-libs/zlib
  34         webengine? ( >=dev-qt/qtwebengine-${QTMIN}:5 )
  35         X? (
  36                 >=dev-qt/qtx11extras-${QTMIN}:5
  37                 x11-libs/libX11
  38                 x11-libs/libXres
  39         )
  40 "
  41 DEPEND="${RDEPEND}
  42         >=kde-frameworks/kiconthemes-${KFMIN}:5
  43         !minimal? ( >=kde-frameworks/plasma-${KFMIN}:5 )
  44         X? ( x11-base/xorg-proto )
  45 "
  46
  47 PATCHES=( "${FILESDIR}/${PN}-5.16.0-no-detailed-mem-message.patch" )
  48
  49 src_configure() {
  50         local mycmakeargs=(
  51                 $(cmake_use_find_package !minimal KF5Plasma)
  52                 $(cmake_use_find_package webengine Qt5WebEngineWidgets)
  53                 $(cmake_use_find_package X X11)
  54         )
  55
  56         ecm_src_configure
  57 }