kde-plasma/kwin/kwin-5.17.2.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 KDE_HANDBOOK="optional"
   7 KDE_TEST="optional"
   8 VIRTUALX_REQUIRED="test"
   9 inherit kde5
  10
  11 DESCRIPTION="Flexible, composited Window Manager for windowing systems on Linux"
  12 LICENSE="GPL-2+"
  13 KEYWORDS="~amd64 ~arm ~arm64 ~x86"
  14 IUSE="caps gles2 multimedia"
  15
  16 COMMON_DEPEND="
  17         $(add_frameworks_dep kactivities)
  18         $(add_frameworks_dep kauth)
  19         $(add_frameworks_dep kcmutils)
  20         $(add_frameworks_dep kcompletion)
  21         $(add_frameworks_dep kconfig)
  22         $(add_frameworks_dep kconfigwidgets)
  23         $(add_frameworks_dep kcoreaddons)
  24         $(add_frameworks_dep kcrash)
  25         $(add_frameworks_dep kdeclarative)
  26         $(add_frameworks_dep kglobalaccel '' '' '5=')
  27         $(add_frameworks_dep ki18n)
  28         $(add_frameworks_dep kiconthemes)
  29         $(add_frameworks_dep kidletime '' '' '5=')
  30         $(add_frameworks_dep kinit)
  31         $(add_frameworks_dep kio)
  32         $(add_frameworks_dep knewstuff)
  33         $(add_frameworks_dep knotifications)
  34         $(add_frameworks_dep kpackage)
  35         $(add_frameworks_dep kservice)
  36         $(add_frameworks_dep ktextwidgets)
  37         $(add_frameworks_dep kwayland)
  38         $(add_frameworks_dep kwidgetsaddons)
  39         $(add_frameworks_dep kwindowsystem X)
  40         $(add_frameworks_dep kxmlgui)
  41         $(add_frameworks_dep plasma)
  42         $(add_plasma_dep breeze)
  43         $(add_plasma_dep kdecoration)
  44         $(add_plasma_dep kscreenlocker)
  45         $(add_qt_dep qtdbus)
  46         $(add_qt_dep qtdeclarative)
  47         $(add_qt_dep qtgui 'gles2=' '' '5=')
  48         $(add_qt_dep qtscript)
  49         $(add_qt_dep qtsensors)
  50         $(add_qt_dep qtwidgets)
  51         $(add_qt_dep qtx11extras)
  52         >=dev-libs/libinput-1.9
  53         >=dev-libs/wayland-1.2
  54         media-libs/fontconfig
  55         media-libs/freetype
  56         media-libs/libepoxy
  57         media-libs/mesa[egl,gbm,gles2?,wayland,X(+)]
  58         virtual/libudev:=
  59         x11-libs/libICE
  60         x11-libs/libSM
  61         x11-libs/libX11
  62         x11-libs/libXi
  63         x11-libs/libdrm
  64         >=x11-libs/libxcb-1.10
  65         >=x11-libs/libxkbcommon-0.7.0
  66         x11-libs/xcb-util-cursor
  67         x11-libs/xcb-util-image
  68         x11-libs/xcb-util-keysyms
  69         x11-libs/xcb-util-wm
  70         caps? ( sys-libs/libcap )
  71 "
  72 RDEPEND="${COMMON_DEPEND}
  73         $(add_frameworks_dep kirigami)
  74         $(add_qt_dep qtquickcontrols)
  75         $(add_qt_dep qtquickcontrols2)
  76         $(add_qt_dep qtvirtualkeyboard)
  77         multimedia? ( $(add_qt_dep qtmultimedia 'gstreamer,qml') )
  78 "
  79 DEPEND="${COMMON_DEPEND}
  80         $(add_qt_dep designer)
  81         $(add_qt_dep qtconcurrent)
  82         x11-base/xorg-proto
  83 "
  84 PDEPEND="
  85         $(add_plasma_dep kde-cli-tools)
  86 "
  87
  88 RESTRICT+=" test"
  89
  90 src_prepare() {
  91         kde5_src_prepare
  92         use multimedia || eapply "${FILESDIR}/${PN}-5.16.80-gstreamer-optional.patch"
  93
  94         # Access violations, bug #640432
  95         sed -e "s/^ecm_find_qmlmodule.*QtMultimedia/#&/" \
  96                 -i CMakeLists.txt || die
  97 }
  98
  99 src_configure() {
 100         local mycmakeargs=(
 101                 $(cmake-utils_use_find_package caps Libcap)
 102         )
 103
 104         kde5_src_configure
 105 }