kde-plasma/kscreenlocker/kscreenlocker-5.18.5.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 ECM_TEST="forceoptional"
   7 KFMIN=5.66.0
   8 PVCUT=$(ver_cut 1-3)
   9 QTMIN=5.12.3
  10 VIRTUALX_REQUIRED="test"
  11 inherit ecm kde.org pam
  12
  13 DESCRIPTION="Library and components for secure lock screen architecture"
  14
  15 LICENSE="GPL-2" # TODO: CHECK
  16 SLOT="5"
  17 KEYWORDS="amd64 ~arm ~arm64 ~ppc64 ~x86"
  18 IUSE="consolekit +pam seccomp"
  19
  20 REQUIRED_USE="seccomp? ( pam )"
  21
  22 RDEPEND="
  23         >=kde-frameworks/kcmutils-${KFMIN}:5
  24         >=kde-frameworks/kconfig-${KFMIN}:5
  25         >=kde-frameworks/kconfigwidgets-${KFMIN}:5
  26         >=kde-frameworks/kcoreaddons-${KFMIN}:5
  27         >=kde-frameworks/kcrash-${KFMIN}:5
  28         >=kde-frameworks/kdeclarative-${KFMIN}:5
  29         >=kde-frameworks/kglobalaccel-${KFMIN}:5
  30         >=kde-frameworks/ki18n-${KFMIN}:5
  31         >=kde-frameworks/kidletime-${KFMIN}:5
  32         >=kde-frameworks/knotifications-${KFMIN}:5
  33         >=kde-frameworks/kpackage-${KFMIN}:5
  34         >=kde-frameworks/ktextwidgets-${KFMIN}:5
  35         >=kde-frameworks/kwayland-${KFMIN}:5
  36         >=kde-frameworks/kwindowsystem-${KFMIN}:5
  37         >=kde-frameworks/kxmlgui-${KFMIN}:5
  38         >=kde-frameworks/solid-${KFMIN}:5
  39         >=dev-qt/qtdbus-${QTMIN}:5
  40         >=dev-qt/qtdeclarative-${QTMIN}:5[widgets]
  41         >=dev-qt/qtgui-${QTMIN}:5
  42         >=dev-qt/qtnetwork-${QTMIN}:5
  43         >=dev-qt/qtwidgets-${QTMIN}:5
  44         >=dev-qt/qtx11extras-${QTMIN}:5
  45         dev-libs/wayland
  46         x11-libs/libX11
  47         x11-libs/libXi
  48         x11-libs/libxcb
  49         x11-libs/xcb-util-keysyms
  50         consolekit? ( sys-auth/consolekit )
  51         pam? ( sys-libs/pam )
  52         seccomp? ( sys-libs/libseccomp )
  53 "
  54 DEPEND="${RDEPEND}
  55         x11-base/xorg-proto
  56 "
  57 PDEPEND="
  58         >=kde-plasma/kde-cli-tools-${PVCUT}:5
  59 "
  60
  61 RESTRICT+=" test"
  62
  63 src_prepare() {
  64         ecm_src_prepare
  65
  66         if ! use test; then
  67                 sed -e "/add_subdirectory(autotests)/ s/^/#/" \
  68                         -i greeter/CMakeLists.txt || die
  69         fi
  70 }
  71
  72 src_test() {
  73         # requires running environment
  74         local myctestargs=(
  75                 -E x11LockerTest
  76         )
  77         ecm_src_test
  78 }
  79
  80 src_configure() {
  81         local mycmakeargs=(
  82                 $(cmake_use_find_package consolekit loginctl)
  83                 -DPAM_REQUIRED=$(usex pam)
  84                 $(cmake_use_find_package pam PAM)
  85                 $(cmake_use_find_package seccomp Seccomp)
  86         )
  87         ecm_src_configure
  88 }
  89
  90 src_install() {
  91         ecm_src_install
  92
  93         use pam && newpamd "${FILESDIR}/kde.pam" kde
  94         use pam && newpamd "${FILESDIR}/kde-np.pam" kde-np
  95
  96         if ! use pam; then
  97                 chown root "${ED}"/usr/$(get_libdir)/libexec/kcheckpass || die
  98                 chmod +s "${ED}"/usr/$(get_libdir)/libexec/kcheckpass || die
  99         fi
 100 }