kde-plasma/kscreenlocker/kscreenlocker-5.15.3.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 KDE_TEST="forceoptional"
   7 VIRTUALX_REQUIRED="test"
   8 inherit kde5 pam
   9
  10 DESCRIPTION="Library and components for secure lock screen architecture"
  11 KEYWORDS="~amd64 ~arm ~arm64 ~x86"
  12 IUSE="consolekit +pam seccomp"
  13
  14 REQUIRED_USE="seccomp? ( pam )"
  15
  16 RDEPEND="
  17         $(add_frameworks_dep kcmutils)
  18         $(add_frameworks_dep kconfig)
  19         $(add_frameworks_dep kconfigwidgets)
  20         $(add_frameworks_dep kcoreaddons)
  21         $(add_frameworks_dep kcrash)
  22         $(add_frameworks_dep kdeclarative)
  23         $(add_frameworks_dep kglobalaccel)
  24         $(add_frameworks_dep ki18n)
  25         $(add_frameworks_dep kidletime)
  26         $(add_frameworks_dep knotifications)
  27         $(add_frameworks_dep kpackage)
  28         $(add_frameworks_dep ktextwidgets)
  29         $(add_frameworks_dep kwayland)
  30         $(add_frameworks_dep kwindowsystem)
  31         $(add_frameworks_dep kxmlgui)
  32         $(add_frameworks_dep solid)
  33         $(add_qt_dep qtdbus)
  34         $(add_qt_dep qtdeclarative 'widgets')
  35         $(add_qt_dep qtgui)
  36         $(add_qt_dep qtnetwork)
  37         $(add_qt_dep qtwidgets)
  38         $(add_qt_dep qtx11extras)
  39         dev-libs/wayland
  40         x11-libs/libX11
  41         x11-libs/libXi
  42         x11-libs/libxcb
  43         x11-libs/xcb-util-keysyms
  44         consolekit? ( sys-auth/consolekit )
  45         pam? ( virtual/pam )
  46         seccomp? ( sys-libs/libseccomp )
  47 "
  48 DEPEND="${RDEPEND}
  49         x11-base/xorg-proto
  50 "
  51 PDEPEND="
  52         $(add_plasma_dep kde-cli-tools)
  53 "
  54
  55 RESTRICT+=" test"
  56
  57 src_prepare() {
  58         kde5_src_prepare
  59
  60         if ! use test; then
  61                 sed -e "/add_subdirectory(autotests)/ s/^/#/" \
  62                         -i greeter/CMakeLists.txt || die
  63         fi
  64 }
  65
  66 src_test() {
  67         # requires running environment
  68         local myctestargs=(
  69                 -E x11LockerTest
  70         )
  71         kde5_src_test
  72 }
  73
  74 src_configure() {
  75         local mycmakeargs=(
  76                 $(cmake-utils_use_find_package consolekit loginctl)
  77                 -DPAM_REQUIRED=$(usex pam)
  78                 $(cmake-utils_use_find_package pam PAM)
  79                 $(cmake-utils_use_find_package seccomp Seccomp)
  80         )
  81         kde5_src_configure
  82 }
  83
  84 src_install() {
  85         kde5_src_install
  86
  87         use pam && newpamd "${FILESDIR}/kde.pam" kde
  88         use pam && newpamd "${FILESDIR}/kde-np.pam" kde-np
  89
  90         if ! use pam; then
  91                 chown root "${ED}"/usr/$(get_libdir)/libexec/kcheckpass || die
  92                 chmod +s "${ED}"/usr/$(get_libdir)/libexec/kcheckpass || die
  93         fi
  94 }