kde-plasma/kmenuedit/kmenuedit-5.14.2.ebuild

   1 # Copyright 1999-2018 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 KDE_HANDBOOK="forceoptional"
   7 inherit kde5
   8
   9 DESCRIPTION="KDE Plasma menu editor"
  10 HOMEPAGE="https://cgit.kde.org/kmenuedit.git"
  11 KEYWORDS="~amd64 ~arm ~x86"
  12 IUSE="+hotkeys"
  13
  14 COMMON_DEPEND="
  15         $(add_frameworks_dep kcompletion)
  16         $(add_frameworks_dep kconfig)
  17         $(add_frameworks_dep kconfigwidgets)
  18         $(add_frameworks_dep kcoreaddons)
  19         $(add_frameworks_dep kdbusaddons)
  20         $(add_frameworks_dep kdelibs4support)
  21         $(add_frameworks_dep ki18n)
  22         $(add_frameworks_dep kiconthemes)
  23         $(add_frameworks_dep kio)
  24         $(add_frameworks_dep kservice)
  25         $(add_frameworks_dep kwidgetsaddons)
  26         $(add_frameworks_dep kxmlgui)
  27         $(add_frameworks_dep sonnet)
  28         $(add_qt_dep qtdbus)
  29         $(add_qt_dep qtgui)
  30         $(add_qt_dep qtwidgets)
  31         $(add_qt_dep qtxml)
  32         hotkeys? ( $(add_plasma_dep khotkeys) )
  33 "
  34 DEPEND="${COMMON_DEPEND}
  35         $(add_frameworks_dep kinit)
  36 "
  37 RDEPEND="${COMMON_DEPEND}
  38         !kde-plasma/kmenuedit:4
  39 "
  40
  41 src_configure() {
  42         local mycmakeargs=(
  43                 $(cmake-utils_use_find_package hotkeys KHotKeysDBusInterface)
  44         )
  45
  46         kde5_src_configure
  47 }