kde-plasma/kinfocenter/kinfocenter-5.17.1.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 CMAKE_MIN_VERSION=3.14.3
   7 KDE_HANDBOOK="forceoptional"
   8 inherit kde5
   9
  10 DESCRIPTION="Utility providing information about the computer hardware"
  11 HOMEPAGE="https://kde.org/applications/system/kinfocenter/"
  12 SRC_URI+=" https://www.gentoo.org/assets/img/logo/gentoo-3d-small.png -> glogo-small.png"
  13 KEYWORDS="~amd64 ~arm ~arm64 ~x86"
  14 IUSE="gles2 ieee1394 +opengl +pci wayland"
  15
  16 REQUIRED_USE="wayland? ( || ( gles2 opengl ) )"
  17
  18 COMMON_DEPEND="
  19         $(add_frameworks_dep kcmutils)
  20         $(add_frameworks_dep kcompletion)
  21         $(add_frameworks_dep kconfig)
  22         $(add_frameworks_dep kconfigwidgets)
  23         $(add_frameworks_dep kcoreaddons)
  24         $(add_frameworks_dep kcrash)
  25         $(add_frameworks_dep kdbusaddons)
  26         $(add_frameworks_dep kdeclarative)
  27         $(add_frameworks_dep ki18n)
  28         $(add_frameworks_dep kiconthemes)
  29         $(add_frameworks_dep kio)
  30         $(add_frameworks_dep kpackage)
  31         $(add_frameworks_dep kservice)
  32         $(add_frameworks_dep kwidgetsaddons)
  33         $(add_frameworks_dep kxmlgui)
  34         $(add_frameworks_dep solid)
  35         $(add_qt_dep qtdbus)
  36         $(add_qt_dep qtdeclarative)
  37         $(add_qt_dep qtgui)
  38         $(add_qt_dep qtwidgets)
  39         x11-libs/libX11
  40         ieee1394? ( sys-libs/libraw1394 )
  41         opengl? (
  42                 $(add_qt_dep qtgui 'gles2=')
  43                 media-libs/mesa[gles2?,X(+)]
  44                 !gles2? ( media-libs/glu )
  45         )
  46         pci? ( sys-apps/pciutils )
  47         wayland? (
  48                 $(add_frameworks_dep kwayland)
  49                 media-libs/mesa[egl]
  50         )
  51 "
  52 DEPEND="${COMMON_DEPEND}
  53         $(add_frameworks_dep plasma)
  54 "
  55 RDEPEND="${COMMON_DEPEND}
  56         $(add_plasma_dep kde-cli-tools)
  57         $(add_qt_dep qtquickcontrols2)
  58 "
  59
  60 src_configure() {
  61         local mycmakeargs=(
  62                 $(cmake-utils_use_find_package ieee1394 RAW1394)
  63                 $(cmake-utils_use_find_package pci PCIUTILS)
  64                 $(cmake-utils_use_find_package wayland EGL)
  65                 $(cmake-utils_use_find_package wayland KF5Wayland)
  66         )
  67
  68         if has_version "dev-qt/qtgui[gles2]"; then
  69                 mycmakeargs+=( $(cmake-utils_use_find_package gles2 OpenGLES) )
  70         else
  71                 mycmakeargs+=( $(cmake-utils_use_find_package opengl OpenGL) )
  72         fi
  73
  74         kde5_src_configure
  75 }
  76
  77 src_install() {
  78         kde5_src_install
  79
  80         # TODO: Make this fully obsolete by /etc/os-release
  81         insinto /etc/xdg
  82         doins "${FILESDIR}"/kcm-about-distrorc
  83
  84         insinto /usr/share/${PN}
  85         doins "${DISTDIR}"/glogo-small.png
  86 }
  87
  88 pkg_postinst() {
  89         kde5_pkg_postinst
  90
  91         if [[ -z "${REPLACING_VERSIONS}" ]]; then
  92                 has_version "net-fs/nfs-utils" || \
  93                         elog "Installing net-fs/nfs-utils will enable the NFS information module."
  94
  95                 has_version "net-fs/samba" || \
  96                         elog "Installing net-fs/samba will enable the Samba status information module."
  97         fi
  98 }