kde-plasma/drkonqi/drkonqi-5.17.1.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit kde5
   7
   8 DESCRIPTION="Plasma crash handler, gives the user feedback if a program crashed"
   9
  10 KEYWORDS="~amd64 ~arm ~arm64 ~x86"
  11 IUSE="X"
  12
  13 COMMON_DEPEND="
  14         $(add_frameworks_dep kcompletion)
  15         $(add_frameworks_dep kconfig)
  16         $(add_frameworks_dep kconfigwidgets)
  17         $(add_frameworks_dep kcoreaddons)
  18         $(add_frameworks_dep kcrash)
  19         $(add_frameworks_dep ki18n)
  20         $(add_frameworks_dep kidletime)
  21         $(add_frameworks_dep kio)
  22         $(add_frameworks_dep kjobwidgets)
  23         $(add_frameworks_dep knotifications)
  24         $(add_frameworks_dep kservice)
  25         $(add_frameworks_dep kwallet)
  26         $(add_frameworks_dep kwayland)
  27         $(add_frameworks_dep kwidgetsaddons)
  28         $(add_frameworks_dep kxmlrpcclient)
  29         $(add_qt_dep qtdbus)
  30         $(add_qt_dep qtgui)
  31         $(add_qt_dep qtwidgets)
  32         $(add_qt_dep qtxml)
  33         X? ( $(add_qt_dep qtx11extras) )
  34 "
  35 DEPEND="${COMMON_DEPEND}
  36         $(add_qt_dep qtconcurrent)
  37 "
  38 RDEPEND="${COMMON_DEPEND}
  39         !<kde-plasma/plasma-workspace-5.10.95:5
  40 "
  41
  42 src_configure() {
  43         local mycmakeargs=(
  44                 $(cmake-utils_use_find_package X Qt5X11Extras)
  45         )
  46         kde5_src_configure
  47 }
  48
  49 src_test() {
  50         # needs network access, bug #698510
  51         local myctestargs=(
  52                 -E "(connectiontest)"
  53         )
  54
  55         kde5_src_test
  56 }
  57
  58 pkg_postinst() {
  59         kde5_pkg_postinst
  60         if ! has_version "sys-devel/gdb"; then
  61                 elog "For more usability consider installing the following package:"
  62                 elog "    sys-devel/gdb - Easier debugging support"
  63         fi
  64 }