kde-plasma/drkonqi/drkonqi-5.13.4.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit kde5
   7
   8 DESCRIPTION="Plasma crash handler, gives the user feedback if a program crashed"
   9
  10 KEYWORDS="~amd64 ~arm ~arm64 ~x86"
  11 IUSE="X"
  12
  13 COMMON_DEPEND="
  14         $(add_frameworks_dep kcompletion)
  15         $(add_frameworks_dep kconfig)
  16         $(add_frameworks_dep kconfigwidgets)
  17         $(add_frameworks_dep kcoreaddons)
  18         $(add_frameworks_dep kcrash)
  19         $(add_frameworks_dep ki18n)
  20         $(add_frameworks_dep kidletime)
  21         $(add_frameworks_dep kio)
  22         $(add_frameworks_dep kjobwidgets)
  23         $(add_frameworks_dep knotifications)
  24         $(add_frameworks_dep kservice)
  25         $(add_frameworks_dep kwallet)
  26         $(add_frameworks_dep kwayland)
  27         $(add_frameworks_dep kwidgetsaddons)
  28         $(add_frameworks_dep kxmlrpcclient)
  29         $(add_qt_dep qtdbus)
  30         $(add_qt_dep qtgui)
  31         $(add_qt_dep qtwidgets)
  32         $(add_qt_dep qtxml)
  33         X? ( $(add_qt_dep qtx11extras) )
  34 "
  35 DEPEND="${COMMON_DEPEND}
  36         $(add_qt_dep qtconcurrent)
  37 "
  38 RDEPEND="${COMMON_DEPEND}
  39         !kde-apps/drkonqi:4
  40         !<kde-plasma/plasma-workspace-5.10.95:5
  41 "
  42
  43 src_configure() {
  44         local mycmakeargs=(
  45                 $(cmake-utils_use_find_package X Qt5X11Extras)
  46         )
  47         kde5_src_configure
  48 }
  49
  50 pkg_postinst() {
  51         kde5_pkg_postinst
  52         if ! has_version "sys-devel/gdb"; then
  53                 elog "For more usability consider installing the following package:"
  54                 elog "    sys-devel/gdb - Easier debugging support"
  55         fi
  56 }