kde-plasma/discover/discover-5.16.4.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 KDE_TEST="forceoptional"
   7 VIRTUALX_REQUIRED="test"
   8 inherit kde5
   9
  10 DESCRIPTION="KDE Plasma resources management GUI"
  11 HOMEPAGE="https://userbase.kde.org/Discover"
  12 KEYWORDS="~amd64 ~arm ~arm64 ~x86"
  13 IUSE="+firmware"
  14
  15 # libmarkdown (app-text/discount) only used in PackageKitBackend
  16 DEPEND="
  17         $(add_frameworks_dep attica)
  18         $(add_frameworks_dep kconfig)
  19         $(add_frameworks_dep kconfigwidgets)
  20         $(add_frameworks_dep kcoreaddons)
  21         $(add_frameworks_dep kcrash)
  22         $(add_frameworks_dep kdbusaddons)
  23         $(add_frameworks_dep kdeclarative)
  24         $(add_frameworks_dep ki18n)
  25         $(add_frameworks_dep kio)
  26         $(add_frameworks_dep kirigami)
  27         $(add_frameworks_dep kitemmodels)
  28         $(add_frameworks_dep knewstuff)
  29         $(add_frameworks_dep knotifications)
  30         $(add_frameworks_dep kwidgetsaddons)
  31         $(add_frameworks_dep kxmlgui)
  32         $(add_qt_dep qtconcurrent)
  33         $(add_qt_dep qtdbus)
  34         $(add_qt_dep qtdeclarative)
  35         $(add_qt_dep qtgui)
  36         $(add_qt_dep qtnetwork)
  37         $(add_qt_dep qtwidgets)
  38         $(add_qt_dep qtxml)
  39         firmware? ( sys-apps/fwupd )
  40 "
  41 RDEPEND="${DEPEND}
  42         $(add_frameworks_dep kirigami)
  43 "
  44
  45 src_prepare() {
  46         kde5_src_prepare
  47         # we don't need it with PackageKitBackend off
  48         punt_bogus_dep KF5 Archive
  49 }
  50
  51 src_configure() {
  52         local mycmakeargs=(
  53                 -DCMAKE_DISABLE_FIND_PACKAGE_packagekitqt5=ON
  54                 -DCMAKE_DISABLE_FIND_PACKAGE_AppStreamQt=ON
  55                 -DCMAKE_DISABLE_FIND_PACKAGE_Snapd=ON
  56                 -DBUILD_FlatpakBackend=OFF
  57                 -DBUILD_FwupdBackend=$(usex firmware)
  58         )
  59
  60         kde5_src_configure
  61 }
  62
  63 src_test() {
  64         # bug 686392: needs network connection
  65         local myctestargs=(
  66                 -E "(knsbackendtest)"
  67         )
  68
  69         kde5_src_test
  70 }