kde-plasma/breeze-gtk/breeze-gtk-5.17.1.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 PYTHON_COMPAT=( python3_{6,7} )
   7 inherit kde5 python-any-r1
   8
   9 DESCRIPTION="Official GTK+ port of Plasma's Breeze widget style"
  10 HOMEPAGE="https://cgit.kde.org/breeze-gtk.git"
  11 LICENSE="LGPL-2.1+"
  12 KEYWORDS="~amd64 ~arm ~arm64 ~x86"
  13 IUSE=""
  14
  15 BDEPEND="${PYTHON_DEPS}
  16         $(add_plasma_dep breeze)
  17         $(python_gen_any_dep 'dev-python/pycairo[${PYTHON_USEDEP}]')
  18         dev-lang/sassc
  19 "
  20
  21 python_check_deps() {
  22         has_version "dev-python/pycairo[${PYTHON_USEDEP}]"
  23 }
  24
  25 pkg_setup() {
  26         python-any-r1_pkg_setup
  27         kde5_pkg_setup
  28 }
  29
  30 src_prepare() {
  31         kde5_src_prepare
  32         if has_version "<dev-util/cmake-3.16_rc1"; then
  33                 eapply "${FILESDIR}"/${PN}-5.16.5-cmake-pre-3.16.patch
  34         fi
  35 }
  36
  37 src_configure() {
  38         local mycmakeargs=(
  39                 -DPython3_EXECUTABLE="${PYTHON}"
  40         )
  41         if has_version "<dev-util/cmake-3.16_rc1"; then
  42                 mycmakeargs=( -DPYTHON_EXECUTABLE="${PYTHON}" )
  43         fi
  44         kde5_src_configure
  45 }