kde-plasma/breeze/breeze-5.5.5.ebuild

   1 # Copyright 1999-2016 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=6
   6
   7 inherit kde5 multibuild
   8
   9 DESCRIPTION="Breeze visual style for the Plasma desktop"
  10 HOMEPAGE="https://projects.kde.org/projects/kde/workspace/breeze"
  11 KEYWORDS="~amd64 ~arm ~x86"
  12 IUSE="qt4"
  13
  14 DEPEND="
  15         $(add_frameworks_dep frameworkintegration)
  16         $(add_frameworks_dep kcmutils)
  17         $(add_frameworks_dep kconfig)
  18         $(add_frameworks_dep kconfigwidgets)
  19         $(add_frameworks_dep kcoreaddons)
  20         $(add_frameworks_dep kguiaddons)
  21         $(add_frameworks_dep ki18n)
  22         $(add_frameworks_dep kwidgetsaddons)
  23         $(add_frameworks_dep kwindowsystem)
  24         $(add_frameworks_dep plasma)
  25         $(add_plasma_dep kdecoration)
  26         $(add_qt_dep qtdbus)
  27         $(add_qt_dep qtgui)
  28         $(add_qt_dep qtwidgets)
  29         $(add_qt_dep qtx11extras)
  30         x11-libs/libxcb
  31         qt4? (
  32                 kde-base/kdelibs:4
  33                 x11-libs/libX11
  34         )
  35 "
  36 RDEPEND="${DEPEND}
  37         $(add_frameworks_dep breeze-icons)
  38         $(add_plasma_dep kde-cli-tools)
  39 "
  40
  41 pkg_setup() {
  42         kde5_pkg_setup
  43         MULTIBUILD_VARIANTS=( kf5 $(usev qt4) )
  44 }
  45
  46 src_configure() {
  47         myconfigure() {
  48                 local mycmakeargs=()
  49
  50                 if [[ ${MULTIBUILD_VARIANT} = qt4 ]] ; then
  51                         mycmakeargs+=( -DUSE_KDE4=true )
  52                 fi
  53
  54                 kde5_src_configure
  55         }
  56
  57         multibuild_foreach_variant myconfigure
  58 }
  59
  60 src_compile() {
  61         multibuild_foreach_variant kde5_src_compile
  62 }
  63
  64 src_install() {
  65         multibuild_foreach_variant kde5_src_install
  66 }