kde-plasma/breeze/breeze-5.17.2.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit kde5
   7
   8 DESCRIPTION="Breeze visual style for the Plasma desktop"
   9 HOMEPAGE="https://cgit.kde.org/breeze.git"
  10 KEYWORDS="~amd64 ~arm ~arm64 ~x86"
  11 IUSE="wayland X"
  12
  13 # drop qtwidgets subslot operator when QT_MINIMAL >= 5.13.0
  14 RDEPEND="
  15         $(add_frameworks_dep frameworkintegration)
  16         $(add_frameworks_dep kcmutils)
  17         $(add_frameworks_dep kconfig)
  18         $(add_frameworks_dep kconfigwidgets)
  19         $(add_frameworks_dep kcoreaddons)
  20         $(add_frameworks_dep kguiaddons)
  21         $(add_frameworks_dep ki18n)
  22         $(add_frameworks_dep kwidgetsaddons)
  23         $(add_frameworks_dep kwindowsystem)
  24         $(add_plasma_dep kdecoration)
  25         $(add_qt_dep qtdbus)
  26         $(add_qt_dep qtdeclarative)
  27         $(add_qt_dep qtgui)
  28         $(add_qt_dep qtwidgets '' '' '5=')
  29         sci-libs/fftw:3.0=
  30         wayland? ( $(add_frameworks_dep kwayland) )
  31         X? (
  32                 $(add_qt_dep qtx11extras)
  33                 x11-libs/libxcb
  34         )
  35 "
  36 DEPEND="${RDEPEND}
  37         $(add_frameworks_dep kpackage)
  38 "
  39 PDEPEND="
  40         $(add_frameworks_dep breeze-icons)
  41         $(add_plasma_dep kde-cli-tools)
  42 "
  43
  44 src_configure() {
  45         local mycmakeargs=(
  46                 $(cmake-utils_use_find_package wayland KF5Wayland)
  47                 $(cmake-utils_use_find_package X XCB)
  48         )
  49         kde5_src_configure
  50 }