kde-plasma/breeze/breeze-5.13.4.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit kde5
   7
   8 DESCRIPTION="Breeze visual style for the Plasma desktop"
   9 HOMEPAGE="https://cgit.kde.org/breeze.git"
  10 KEYWORDS="~amd64 ~arm ~arm64 ~x86"
  11 IUSE="wayland X"
  12
  13 RDEPEND="
  14         $(add_frameworks_dep frameworkintegration)
  15         $(add_frameworks_dep kcmutils)
  16         $(add_frameworks_dep kconfig)
  17         $(add_frameworks_dep kconfigwidgets)
  18         $(add_frameworks_dep kcoreaddons)
  19         $(add_frameworks_dep kguiaddons)
  20         $(add_frameworks_dep ki18n)
  21         $(add_frameworks_dep kwidgetsaddons)
  22         $(add_frameworks_dep kwindowsystem)
  23         $(add_plasma_dep kdecoration)
  24         $(add_qt_dep qtdbus)
  25         $(add_qt_dep qtdeclarative)
  26         $(add_qt_dep qtgui)
  27         $(add_qt_dep qtwidgets)
  28         wayland? ( $(add_frameworks_dep kwayland) )
  29         X? (
  30                 $(add_qt_dep qtx11extras)
  31                 x11-libs/libxcb
  32         )
  33 "
  34 DEPEND="${RDEPEND}
  35         $(add_frameworks_dep kpackage)
  36 "
  37 PDEPEND="
  38         $(add_frameworks_dep breeze-icons)
  39         $(add_plasma_dep kde-cli-tools)
  40 "
  41
  42 src_configure() {
  43         local mycmakeargs=(
  44                 $(cmake-utils_use_find_package wayland KF5Wayland)
  45                 $(cmake-utils_use_find_package X XCB)
  46         )
  47         kde5_src_configure
  48 }