kde-frameworks/kidletime/kidletime-5.51.0.ebuild

   1 # Copyright 1999-2018 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 KDE_TEST="false"
   7 inherit kde5
   8
   9 DESCRIPTION="Framework for detection and notification of device idle time"
  10 LICENSE="LGPL-2+"
  11 KEYWORDS="~amd64 ~arm ~arm64 ~x86"
  12 IUSE="X xscreensaver"
  13
  14 REQUIRED_USE="xscreensaver? ( X )"
  15
  16 RDEPEND="
  17         $(add_qt_dep qtgui)
  18         $(add_qt_dep qtwidgets)
  19         X? (
  20                 $(add_qt_dep qtx11extras)
  21                 x11-libs/libX11
  22                 x11-libs/libxcb
  23                 x11-libs/libXext
  24         )
  25         xscreensaver? (
  26                 $(add_qt_dep qtdbus)
  27                 x11-libs/libXScrnSaver
  28         )
  29 "
  30 DEPEND="${RDEPEND}"
  31
  32 src_prepare() {
  33         kde5_src_prepare
  34         if ! use xscreensaver; then
  35                 sed -i -e "s/\${X11_Xscreensaver_FOUND}/0/" CMakeLists.txt || die
  36         fi
  37 }
  38
  39 src_configure() {
  40         local mycmakeargs=(
  41                 $(cmake-utils_use_find_package X X11)
  42                 $(cmake-utils_use_find_package X XCB)
  43         )
  44
  45         kde5_src_configure
  46 }