kde-frameworks/frameworkintegration/frameworkintegration-5.67.0.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 ECM_QTHELP="false"
   7 PVCUT=$(ver_cut 1-2)
   8 QTMIN=5.12.3
   9 VIRTUALX_REQUIRED="test"
  10 inherit ecm kde.org
  11
  12 DESCRIPTION="Framework for integrating Qt applications with KDE Plasma workspaces"
  13
  14 LICENSE="LGPL-2+"
  15 KEYWORDS="amd64 ~arm arm64 ~ppc64 x86"
  16 IUSE="appstream"
  17
  18 # drop qtwidgets subslot operator when QT_MINIMAL >= 5.14.0
  19 RDEPEND="
  20         >=dev-qt/qtgui-${QTMIN}:5
  21         >=dev-qt/qtwidgets-${QTMIN}:5=
  22         =kde-frameworks/kconfig-${PVCUT}*:5
  23         =kde-frameworks/kconfigwidgets-${PVCUT}*:5
  24         =kde-frameworks/ki18n-${PVCUT}*:5
  25         =kde-frameworks/kiconthemes-${PVCUT}*:5
  26         =kde-frameworks/knewstuff-${PVCUT}*:5
  27         =kde-frameworks/knotifications-${PVCUT}*:5
  28         appstream? (
  29                 app-admin/packagekit-qt
  30                 dev-libs/appstream[qt5]
  31         )
  32 "
  33 DEPEND="${RDEPEND}
  34         =kde-frameworks/kpackage-${PVCUT}*:5
  35         =kde-frameworks/kwidgetsaddons-${PVCUT}*:5
  36 "
  37
  38 # requires running kde environment
  39 RESTRICT+=" test"
  40
  41 src_configure() {
  42         local mycmakeargs=(
  43                 $(cmake_use_find_package appstream AppStreamQt)
  44                 $(cmake_use_find_package appstream packagekitqt5)
  45         )
  46
  47         ecm_src_configure
  48 }