kde-frameworks/frameworkintegration/frameworkintegration-5.37.0.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 VIRTUALX_REQUIRED="test"
   7 inherit kde5
   8
   9 DESCRIPTION="Framework for integrating Qt applications with KDE Plasma workspaces"
  10 LICENSE="LGPL-2+"
  11 KEYWORDS="amd64 ~arm ~arm64 x86"
  12 IUSE="appstream X"
  13
  14 RDEPEND="
  15         $(add_frameworks_dep kconfig)
  16         $(add_frameworks_dep kconfigwidgets)
  17         $(add_frameworks_dep ki18n)
  18         $(add_frameworks_dep kiconthemes)
  19         $(add_frameworks_dep knewstuff)
  20         $(add_frameworks_dep knotifications)
  21         $(add_frameworks_dep kpackage)
  22         $(add_frameworks_dep kwidgetsaddons)
  23         $(add_qt_dep qtgui)
  24         $(add_qt_dep qtwidgets)
  25         appstream? (
  26                 app-admin/packagekit-qt
  27                 dev-libs/appstream[qt5]
  28         )
  29         X? (
  30                 $(add_qt_dep qtx11extras)
  31                 x11-libs/libxcb
  32         )
  33 "
  34 DEPEND="${RDEPEND}"
  35
  36 # requires running kde environment
  37 RESTRICT+=" test"
  38
  39 src_prepare() {
  40         punt_bogus_dep Qt5 DBus
  41         kde5_src_prepare
  42 }
  43
  44 src_configure() {
  45         local mycmakeargs=(
  46                 $(cmake-utils_use_find_package appstream AppStreamQt)
  47                 $(cmake-utils_use_find_package appstream packagekitqt5)
  48                 $(cmake-utils_use_find_package X XCB)
  49         )
  50
  51         kde5_src_configure
  52 }