kde-frameworks/extra-cmake-modules/extra-cmake-modules-5.51.0.ebuild

   1 # Copyright 1999-2018 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 PYTHON_COMPAT=( python{2_7,3_{4,5,6,7}} )
   7 ECM_KDEINSTALLDIRS="false"
   8 KDE_AUTODEPS="false"
   9 KDE_DEBUG="false"
  10 KDE_QTHELP="false"
  11 KDE_TEST="false"
  12 inherit kde5 python-any-r1
  13
  14 DESCRIPTION="Extra modules and scripts for CMake"
  15 HOMEPAGE="https://cgit.kde.org/extra-cmake-modules.git"
  16
  17 LICENSE="BSD"
  18 KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86 ~amd64-fbsd"
  19 IUSE="doc test"
  20
  21 DEPEND="
  22         doc? (
  23                 ${PYTHON_DEPS}
  24                 $(python_gen_any_dep 'dev-python/sphinx[${PYTHON_USEDEP}]')
  25         )
  26         test? (
  27                 $(add_qt_dep qtcore)
  28                 $(add_qt_dep linguist-tools)
  29         )
  30 "
  31 RDEPEND="
  32         app-arch/libarchive[bzip2]
  33 "
  34
  35 PATCHES=( "${FILESDIR}/${PN}-5.49.0-no-fatal-warnings.patch" )
  36
  37 python_check_deps() {
  38         has_version "dev-python/sphinx[${PYTHON_USEDEP}]"
  39 }
  40
  41 pkg_setup() {
  42         use doc && python-any-r1_pkg_setup
  43 }
  44
  45 src_configure() {
  46         local mycmakeargs=(
  47                 -DBUILD_QTHELP_DOCS=$(usex doc)
  48                 -DBUILD_HTML_DOCS=$(usex doc)
  49                 -DBUILD_MAN_DOCS=$(usex doc)
  50                 -DDOC_INSTALL_DIR=/usr/share/doc/"${PF}"
  51         )
  52         use test && mycmakeargs+=( -DCMAKE_DISABLE_FIND_PACKAGE_PythonModuleGeneration=ON )
  53
  54         kde5_src_configure
  55 }
  56
  57 src_test() {
  58         # ECMToolchainAndroidTest passes but then breaks src_install
  59         # ECMPoQmToolsTest is broken, bug #627806
  60         local myctestargs=(
  61                 -E "(ECMToolchainAndroidTest|ECMPoQmToolsTest)"
  62         )
  63
  64         kde5_src_test
  65 }