kde-frameworks/extra-cmake-modules/extra-cmake-modules-5.46.0.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
   7 KDE_AUTODEPS="false"
   8 KDE_DEBUG="false"
   9 KDE_QTHELP="false"
  10 KDE_TEST="false"
  11 inherit kde5 python-any-r1
  12
  13 DESCRIPTION="Extra modules and scripts for CMake"
  14 HOMEPAGE="https://cgit.kde.org/extra-cmake-modules.git"
  15
  16 LICENSE="BSD"
  17 KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86 ~amd64-fbsd"
  18 IUSE="doc test"
  19
  20 DEPEND="
  21         doc? (
  22                 ${PYTHON_DEPS}
  23                 $(python_gen_any_dep 'dev-python/sphinx[${PYTHON_USEDEP}]')
  24         )
  25         test? (
  26                 $(add_qt_dep qtcore)
  27                 $(add_qt_dep linguist-tools)
  28         )
  29 "
  30 RDEPEND="
  31         app-arch/libarchive[bzip2]
  32 "
  33
  34 python_check_deps() {
  35         has_version "dev-python/sphinx[${PYTHON_USEDEP}]"
  36 }
  37
  38 pkg_setup() {
  39         use doc && python-any-r1_pkg_setup
  40 }
  41
  42 src_configure() {
  43         local mycmakeargs=(
  44                 -DBUILD_HTML_DOCS="$(usex doc)"
  45                 -DBUILD_MAN_DOCS="$(usex doc)"
  46                 -DDOC_INSTALL_DIR="/usr/share/doc/${PF}"
  47         )
  48         use test && mycmakeargs+=( -DCMAKE_DISABLE_FIND_PACKAGE_PythonModuleGeneration=ON )
  49
  50         cmake-utils_src_configure
  51 }
  52
  53 src_test() {
  54         # ECMToolchainAndroidTest passes but then breaks src_install
  55         # ECMPoQmToolsTest is broken, bug #627806
  56         local myctestargs=(
  57                 -E "(ECMToolchainAndroidTest|ECMPoQmToolsTest)"
  58         )
  59
  60         kde5_src_test
  61 }