kde-apps/okular/okular-18.12.3.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 KDE_HANDBOOK="forceoptional"
   7 KDE_TEST="forceoptional"
   8 VIRTUALX_REQUIRED="test"
   9 inherit kde5
  10
  11 DESCRIPTION="Universal document viewer based on KDE Frameworks"
  12 HOMEPAGE="https://okular.kde.org https://www.kde.org/applications/graphics/okular"
  13 KEYWORDS="amd64 ~arm64 x86"
  14 IUSE="chm crypt djvu epub +image-backend markdown mobi mobile +pdf plucker +postscript share speech +tiff"
  15
  16 DEPEND="
  17         $(add_frameworks_dep kactivities)
  18         $(add_frameworks_dep karchive)
  19         $(add_frameworks_dep kbookmarks)
  20         $(add_frameworks_dep kcompletion)
  21         $(add_frameworks_dep kconfig)
  22         $(add_frameworks_dep kconfigwidgets)
  23         $(add_frameworks_dep kcoreaddons)
  24         $(add_frameworks_dep kcrash)
  25         $(add_frameworks_dep kio)
  26         $(add_frameworks_dep kjs)
  27         $(add_frameworks_dep kparts)
  28         $(add_frameworks_dep kpty)
  29         $(add_frameworks_dep kwallet)
  30         $(add_frameworks_dep threadweaver)
  31         $(add_qt_dep qtdbus)
  32         $(add_qt_dep qtgui)
  33         $(add_qt_dep qtprintsupport)
  34         $(add_qt_dep qtsvg)
  35         $(add_qt_dep qtwidgets)
  36         media-libs/freetype
  37         media-libs/phonon[qt5(+)]
  38         sys-libs/zlib
  39         chm? (
  40                 $(add_frameworks_dep khtml)
  41                 dev-libs/chmlib
  42         )
  43         crypt? ( app-crypt/qca:2[qt5(+)] )
  44         djvu? ( app-text/djvu )
  45         epub? ( app-text/ebook-tools )
  46         image-backend? (
  47                 $(add_kdeapps_dep libkexiv2)
  48                 $(add_qt_dep qtgui 'gif,jpeg,png')
  49         )
  50         markdown? ( app-text/discount )
  51         mobi? ( $(add_kdeapps_dep kdegraphics-mobipocket) )
  52         pdf? ( app-text/poppler[qt5] )
  53         plucker? ( virtual/jpeg:0 )
  54         postscript? ( app-text/libspectre )
  55         share? ( $(add_frameworks_dep purpose) )
  56         speech? ( $(add_qt_dep qtspeech) )
  57         tiff? ( media-libs/tiff:0 )
  58 "
  59 RDEPEND="${DEPEND}
  60         image-backend? ( $(add_frameworks_dep kimageformats) )
  61         mobile? (
  62                 $(add_frameworks_dep kirigami)
  63                 $(add_qt_dep qtquickcontrols)
  64         )
  65 "
  66
  67 PATCHES=(
  68         "${FILESDIR}/${PN}-18.08.0-tests.patch"
  69         "${FILESDIR}/${PN}-18.12.0-tests.patch"
  70 )
  71
  72 src_prepare() {
  73         kde5_src_prepare
  74         use mobile || cmake_comment_add_subdirectory mobile
  75         use test || cmake_comment_add_subdirectory conf/autotests
  76 }
  77
  78 src_configure() {
  79         local mycmakeargs=(
  80                 $(cmake-utils_use_find_package chm CHM)
  81                 $(cmake-utils_use_find_package crypt Qca-qt5)
  82                 $(cmake-utils_use_find_package djvu DjVuLibre)
  83                 $(cmake-utils_use_find_package epub EPub)
  84                 $(cmake-utils_use_find_package image-backend KF5KExiv2)
  85                 $(cmake-utils_use_find_package markdown Discount)
  86                 $(cmake-utils_use_find_package mobi QMobipocket)
  87                 $(cmake-utils_use_find_package pdf Poppler)
  88                 $(cmake-utils_use_find_package plucker JPEG)
  89                 $(cmake-utils_use_find_package postscript LibSpectre)
  90                 $(cmake-utils_use_find_package share KDEExperimentalPurpose)
  91                 $(cmake-utils_use_find_package speech Qt5TextToSpeech)
  92                 $(cmake-utils_use_find_package tiff TIFF)
  93         )
  94
  95         kde5_src_configure
  96 }
  97
  98 src_test() {
  99         # mainshelltest hangs, chmgeneratortest fails, bug #603116
 100         # parttest hangs, bug #641728
 101         local myctestargs=(
 102                 -E "(mainshelltest|chmgeneratortest|parttest)"
 103         )
 104
 105         kde5_src_test
 106 }